Опис та використання вказівки розгалуження 


Мы поможем в написании ваших работ!



ЗНАЕТЕ ЛИ ВЫ?

Опис та використання вказівки розгалуження



Вказівка розгалуження в мові програмування Паскаль може записуватися в повній або в скороченій формах.

  1. Повна форма:
if <умова> then <вказівка1> else <вказівка2>;

Дія оператора: Якщо умова справджується, то виконується вказівка 1, якщо ні – то вказівка 2.

2. Скорочена форма:

Іf <умова> then<вказівка>;

Дія оператора: Якщо умова істинна, то виконується вказівка, якщо ні, то вказівка не виконується.

Службові слова, які використовуються в умовній вказівці, ма­ють зміст if — якщо, then — то, else — інакше.

Умова — це вираз булевого типу. Умова може бути простою або складеною.

Наприклад.

1. Проста умова: а<5, с>=а, х=0,а<b

2. Складена умова (а>5) and (a<10), (а=2) or (b=3)

Складена умова записується з допомогою логічних операцій and — і, or — чи (або), not — не. При записі умови можна використовувати всі можливі операції відношення. Результатом виразу умови завжди буде величина булевого типу.

 

 

 

4. вказівка вибору CASE

Довільна вказівка в програмі може бути помічена міткою. Мітка вказівки записується перед нею і відділяється від неї двокрап­кою.

Мітка — це довільне ціле число в інтервалі від 0 до 9999 або довільний ідентифікатор (тобто ім'я мітки записується згідно з правилами запису ідентифікаторів).

Однією міткою може бути помічена тільки одна вказівка. Ідентифікатор мітки не повинен співпадати з ідентифікатором змінної або константи.

Вказівка вибору (варіанту)

У випадку, коли необхідно використовувати декілька вказівок розгалуження, вкладених одна в одну, то краще замінити їх вка­зівкою вибору.

Вказівка вибору записується у вигляді:

Зауваження!! Слова синоніми: Варіант=Селектор, Значеня=Мітка
Case <вираз> of

значення1:<вказівка1>;

значення2:<вказівка2>;

значенняМ:<вказівкаM>

end;

Дія оператора: Якщо значення виразу збігається зі значенням з деякого списку, то виконується відповідний оператор, а інші оператори не виконуються Якщо ні одне з значень не співпадає зі значенням виразу, то виконується вказівка, яка знаходиться після вказівки варіанту, тобто після службового сло­ва end.

Вираз, який записується між службовим словом case і of, нази­вається селектором. Селектор повинен належати до одного з ці­лого, булевого, символьного типів або типу користувача. Дійсні і рядкові типи в селекторах використовувати не можна.

Мітки варіантів — константи, типи яких повинні співпадати з типом селектора. Всі мітки варіантів повинні бути різними. Якщо одній вказівці у вказівці варіанту відповідає декілька міток, то вони перераховуються через кому.

Виконується вказівка варіанту так.

Примітка.

Мітки варіанту не потрібно описувати в розділі міток Label і їх не можна використовувати у вказівці безумовного переходу Goto.

Наприклад.

Скласти програму, яка визначає пору року за порядковим но­мером місяця.

Program PORA;

Var MONTH: integer;

Begin

Write( 'Введіть порядковий номер місяця (від 1 до 12): ' );

readln(MONTH);

Case MONTH of

3,4,5:writeln('Becнa');

6,7,8: writeln ('Літо');

9,10,11:writeln('Ociнь');

12,1,2:writeln('Зимa')

end;

End.

ВКАЗІВКИ ПОВТОРЕННЯ (ЦИКЛУ)

5. Вказівка повторення з параметром FOR

Цикл – це вид управляючої структури, що дозволяє кілька разів повторити задану кількість операторів. Цикли - основний засіб у програмуванні, що дозволяє коротко записувати алгоритм, який здійснює велику кількість дій.

Для реалізації циклічних алгоритмів у мові Паскаль використовуються оператори повторення (цикли):

* оператор циклу з параметром (For);

* оператор циклу з передумовою (While);

* оператор циклу з післяумовою (Repeat).

Оператор циклу з параметром передбачає повторне виконання деякого оператора з одночасною зміною значення, що присвоюється керуючою змінною (параметру цього циклу). Він має вид:

а) зі значенням 1 кроку зміни параметра:

For < параметр >:= <вираз1 > to <вираз2 >do <оператор >

Дія оператора: Параметрові циклу присвоюється значення виразу 1. Якщо це значення менше-рівне, ніж значення виразу 2, то виконується оператор. Після виконання оператора значення параметра автоматично збільшується на 1 і знову порівнюється зі значенням виразу 2 і т.д. Коли значення параметра стане більшим, ніж значення виразу 2, то виконується наступний після циклу оператор.

або

б) зі значенням -1 кроку зміни параметра:

For < параметр >:=< вираз1 > downto <вираз2 > do <оператор>

Дія оператора: Ця команда діє як попередня, але крок зміни параметра є –1.

Оператор - тіло циклу.

Параметр циклу, вираз1 і вираз2 повинні бути одного й того ж скалярного типу (крім дійсного). Вираз1 і вираз2 обчислюється лише один раз - при вході в цикл, і, отже, повинні бути визначені до входу в цикл і не можуть бути змінені в тілі циклу.

Якщо вираз1 і вираз2 розділяє службове слово to, то після виконання оператора (тіла циклу) параметр циклу v приймає значення Succ(v), якщо ж дільником виразу1 і виразу2 служить слово downto, то параметр циклу v після виконання тіла циклу приймає значення Pred(v).

Приклад:

Піднести будь-яке дійсне число а до будь-якого цілого степення n.

Розв'язок:

program Stepin;

Var

a,p:real;

i,n:integer;

Begin

write('введіть a - основу степеня, а=');

readln(a);

write('введіть ціле n - показник степеня, n=');

readln(n);

p:=1;

for i:=1 to n do

p:= p * a;

writeln('p=',p)

End.

6. Вказівка повторення WHILE

Оператор For використовується лише у випадку, коли заздалегідь відома кількість повторень тіла циклу. У більш загальному випадку, коли кількість повторень заздалегідь невідома, а задана деяка умова закінчення (або продовження) циклу, у мові Pascal використовують інші оператори повторення: оператор циклу з передумовою While і оператор циклу з післяумовою Repeat.

Вказівка циклу з передумовою:

 
 

 


Дія оператора:

Оператор (тіло циклу) виконується до тих пір, поки умова істинна. Якщо при першій перевірці умова виявилась хибною, оператор не виконується. Зазначений оператор виконується нуль, один або декілька разів, поки умова справджується.

Тіло циклу WHILE виконується до тих пір, поки умова приймає значення True. Дії, що містяться в тілі циклу, будуть виконані у крайньому випадку один раз. Таким чином, не виконання умови є умовою закінчення циклу.

 

 
 
Приклад 1. Роздрукувати символи латинського алфавіту. а) звичайний порядок: programlatsimvol; var S:char; begin S:='A'; while S<='Z' do begin writeln(S); S:=succ(S); end end. б) у зворотному порядку: programlatsimvol; var S:char; begin S:='Z'; while S>='A' do begin writeln(S); S:=pred(S); end end.

 


 

 


7. Вказівка повторення REPEAT

 

Оператор For використовується лише у випадку, коли заздалегідь відома кількість повторень тіла циклу. У більш загальному випадку, коли кількість повторень заздалегідь невідома, а задана деяка умова закінчення (або продовження) циклу, у мові Pascal використовують інші оператори повторення: оператор циклу з передумовою While і оператор циклу з післяумовою Repeat.

Оператор циклу з післяумовою визначений діаграмою:

 

 


Оператор циклу з післяумовою передбачає повторне виконання деякого оператора(ів) до тих пір, поки не виконається умова.. Він має вид:

 

REPEAT <оператор1 > <оператор2 > <оператор3 > *** <оператор n > UNTIL <умова>;

Дія оператора: Спочатку виконуються зазначені оператори, а пізніше перевіряється умова. Якщо умова справджується (істинна), то виконання циклу завершується, якщо ні, то оператори виконуються ще раз, і так далі.

Тіло циклу Repeat виконується до тих пір, поки умова приймає значення False. Дії, що містяться в тілі циклу, будуть виконані у крайньому випадку один раз. Таким чином, виконання умови є умовою закінчення циклу.

 

ВКЛАДЕНІ ЦИКЛИ: Вкладені цикли– це декілька циклів записаних один за одним. Наприклад: for i:=1 to 10 do for j:=1 to 15 do <оператори>

Зауваження:

Repeat Until KeyPressed – умова, чи

натиснена клавіша (пауза);

 

 
 
Приклад 1. Роздрукувати символи латинського алфавіту. а) звичайний порядок: programlatsimvol; var S:char; begin S:='A'; Repeat write(S); S:=succ(S); until S>'Z' end. б) у зворотному порядку: programlatsimvol; var S:char; begin S:='Z'; Repeat write(S); S:=pred(S); until S<'A' end.


 


Підпрограми

Підпрограми призначені для реалізації алгоритмів опрацювання окремих частин деякої складної задачі. Вони дають змогу реалізовувати концепцію структурного програмування, суть якого полягає в розкладанні складної задачі на послідовність простих підзадач і в складанні для алгоритмів розв’язування кожної підзадачі відповідних підпрограм. Розрізняють два види підпрогрампідпрограми-процедури та підпрограми-функції. Підпрограми поділяються на: стандартні та підпрограми користувача.

Стандартні підпрограми створювати не потрібно — вони містяться у стандартних модулях System, Crt, Dos, Graph тощо.

Підпрограма користувача — це пойменована група команд, яку створюють і описують в основній програмі в розділах procedure або function і до якої звертаються з будь-якого місця програми потрібну кількість разів.

1. Процедури (procedure). Загальний опис процедури:

procedure <назва> (<список формальних параметрів>); <розділи описів і оголошень процедури>; begin <розділ команд процедури> end;

У списку формальних параметрів перераховують змінні разом із зазначенням їхніх типів. Розрізняють параметри-аргументи (інший термін: параметри-значення) — вхідні дані для процедури, і параметри-результати (інший термін: параметри-змінні), через які можна повертати результати роботи процедури в основну програму. Перед списками параметрів-результатів кожного типу записують слово var.

Зауважимо, що масиви фіксованих розмірів у списках формальних параметрів не можна описувати за допомогою слова array (див. зразки програм).

Розділи описів і оголошень у підпрограмах мають таку саму структуру як і в основній програмі.

Приклад1. Розглянемо процедуру з назвою Cina, яка визначає с — вартість k хвилин телефонної розмови з похвилинною оплатою 0.6 грн. + 20% ПДВ.

procedure Cina(k:integer; var c:real);

Begin

c:=k*0.6; c:=c+0.2*c;

end;

У наведеному прикладі k є формальним параметром-аргументом, с — формальним параметром-результатом.

До процедури звертаються з розділу команд основної програми або іншої підпрограми.

Звернення до процедури:

<назва процедури> (<список фактичних параметрів>);

Параметри, які записують у команді виклику процедури, називаються фактичними. Фактичними параметрами-аргументами можуть бути сталі, змінні, вирази, а параметрами-результатами — лише змінні. Типи даних тут не зазначають.

Між фактичними і формальними параметрами має бути відповідність за кількістю й типами. Зверніть увагу, відповідні фактичні та формальні параметри можуть мати різні імена.

Команда виклику функціонує так: значення фактичних параметрів присвоюються відповідним формальним параметрам процедури, виконується процедура, визначаються параметри-результати, значення яких надаються (повертаються) відповідним фактичним параметрам у команді виклику.

Змінні, описані в розділі описів основної програми, називаються глобальними. Вони діють у всіх підпрограмах, з яких складається програма. Змінні, описані в розділі описів конкретної процедури, називаються локальними. Вони діють тільки в межах даної процедури.

Процедури можуть отримувати і повертати значення не тільки через параметри-результати, але й через глобальні змінні. Тому списків параметрів у процедурі може і не бути.

 

2. Функції (function). Функція, на відміну від процедури, може повертати в місце виклику лише один результат простого стандартного типу.

Загальний опис функції:

function <назва>(<список формальних параметрів>): <тип функції>; <розділи описів і оголошень функції>; begin <розділ команд функції, де має бути така команда: назва:=вираз> end;

У розділі команд функції має бути команда присвоєння значення деякого виразу назві функції. Результат функції повертається в основну програму через її назву (як і випадку використання стандартних функцій, таких як sin, cos).

Звернення до функції:

<назва> (<список фактичних параметрів>).

Приклад1. Створимо функцію для обчислення tg(x) та обчислимо значення виразу tg(x)+ctg(x)+tg2(x).

program Myfunc;

uses Crt;

var x,y:real;

function tg(x:real):real;

Begin

tg:=sin(x)/cos(x)

end;

begin clrscr;

writeln ('Введіть х');

readln (x);

y:=tg(x)+1/tg(x)+sqr(tg(x));

writeln ('y=', y:5:2); readln

End.

3. Рекурсивні функції. Рекурсією називається алгоритмічна конструкція, де підпрограма викликає сама себе. Рекурсія дає змогу записувати циклічний алгоритм, не використовуючи команду циклу. Розглянемо спочатку поняття стеку.

Стек — це структура даних в оперативної пам’яті, де дані запам’ятовуються і зберігаються за принципом «перший прийшов — останнім пішов». Аналогом у військовій справі є ріжок для набоїв до автомата.

Приклад1. Рекурсивна функція обчислення суми цілих чисел від a до b має вигляд:

function Suma(a,b:integer):integer;

Begin

if a=b then Suma:= a {Це стоп-умова рекурсії}

else Suma:= b + Suma(a, b–1) {Це неявний цикл}

end;

 

Приклад2. Скласти рекурсивну функцiю Factorial для обчислення факторіала числа n! = 1·2·3·...·n, (0! = 1, 1! = 1), яка грунтується на багаторазовому (рекурсивному) застосуваннi формули n! = n·(n – 1)!.

function Factorial(n: integer): integer;

Begin

if n = 0 then Factorial:= 1 {Це стоп-умова}

else Factorial:= n * Factorial(n–1)

end;

Зауваження. Застосовуючи рекурсію, потрібно правильно складати стоп-умови, які забезпечують закінчення циклічних обчислень.


Масиви

Масив (array) — це скінчений набір елементів одного (базового) типу, які зберігаються в послідовно розташованих комірках оперативної пам’яті і мають спільну назву.

У математиці поняттю мaсив відповідають поняття вектора та матриці. Розрізняють одно (рядки, стрічки, вектори)- та багатовимірні масиви. Двовимірний масив даних — це таблиця, що складається з декількох рядків.

1. Одновимірні масиви (рядки, вектори):

Загальний вигляд конструкції опису типу масиву такий:

TYPE <назва типу>=array [<розмір>] of<назва базового типу>;

можна і так:

<список змінних>:array [<розмір>] of<назва базового типу>;

Розмір (кількість елементів) масиву найчастіше задають у вигляді діапазону або назви деякого перерахованого типу даних.

Описати масив можна у розділі опису типів type, у розділі констант const, або у розділі оголошення змінних var. Назви типів масивів і змінних-масивів придумує користувач.

Приклад. Розгляньте: 1) опис типу масивів (назва типу mymasyv), 2) оголошення cталого масиву (масиву-константи) vydatky типу mymasyv і 3) оголошення змінних-масивів a, a1 типу mymasyv та масивів: b (він має 7 елементів цілого типу), c (має 100 елементів-символів, тобто даних типу char).

type mymasyv= array [1..10] of real;

day=(mon, tue, wed, the, fri, sat, sun);

const vydatky: mymasyv =(1.2, 1, 1, 2, 18, 2.4, 8.97, 3, 7, 1.3);

var a, a1: mymasyv;

b: array [day] of integer;

c: array [1..100] of char;

Над масивами визначена єдина команда копіювання: a:=a1 – усі значення масиву a1 будуть присвоєні відповідним еле­ментам масиву a. Усі інші операції, наприклад, присвоєння конкретних значень, додавання, множення тощо, визначені лише над елементами масиву.

Доступ до елемента масиву здійснюється через назву масиву і номер елемента. Цей номер (його часто називають індексом) записується в квадратних дужках, наприклад, a[1] - перший елемент масиву а, b[tue]-другий елемент масиву b.

Щоб опрацювати всі елементи масиву використовують команду циклу for (чи while або repeat).

Приклад. Елементам описаних масивів можна надати значення так: a[1]:=15.1; b[tue]:=3; с[1]:=’a’; c[2]:=’b’. Сталі елементи мають такі значення: vydatky[1]=1.2; vydatky[2]=1; …; vydatky[10]=1.3.

Приклад. Створити масив з перших ста цілих чисел і обчислити суму всіх його елементів можна так: s:=0; for i:=1 to 100 do begin a[i]:=i; s:=s+a[i] end; writeln(s);

Задачі відшукуання в масиві конкретних даних розв’язують методом сканування (перебирання, перегляду) усіх елементів масиву за допомогою циклу і умовної команди, де зазначають умову пошуку.

Задача 1. Нехай yk — це число викликів, які поступають на АТС за k-ту секундy. Припустимо, що yk — випадкове число зі значенням від 0 до 6, яке генерується формулою yk=trunc(abs(7sin(k))). Утворити масив y з десятьма елементами. Обчислити суму викликів за перші 10 секунд роботи АТС та максимальну кількість викликів, що були за деяку одну секунду. Вивести результати обчислень.

program ATS;

uses Crt;

type vyklyk= array [1..10] of integer;

var y: vyklyk; max, s, i: integer;

Begin

clrscr;

max:=0; s:=0; {Припустимо, що max=0}

for i:=1 to 10 do

Begin

y[i]:=trunc(abs(7*sin(i))); {Обчислимо кількість викликів}

write ('Кількість викликів за ', i, '–ту секунду: '); {за і-ту секунду}

writeln (y[i]:5); {Виведемо цю кількість}

s:=s+y[i]; {Обчислимо суму викликів}

if y[i]>max then max:=y[i]; {Обчислимо max значення }

end;

writeln ('Кількість викликів за 10 секунд = ', s:3);

write ('Максимальна кількість викликів за одну ');

writeln('секунду = ', max:3);

Readln

End.

Зауваження. Випадкове ціле число зі значенням від 0 до 6 можна згенерувати також за допомогою функції random (7). На початку виконуваного блоку слід записати виклик процедури randomize (вона забезпечить іншу послідовність випадкових чисел під час виконання програми вдруге).

Задача 2. Утворити масив y, елементи якого обчислюються за формулою yk=ln(k)–3, де . Побудувати масив g, який складається з від'ємних елементів масиву y. Вивести результати обчислень. Якщо шуканих величин немає, вивести про це повідомлення.

У наступній програмі змінна n визначає кількість від’ємних елементів у новому масиві.

program DvaMasyvy;

uses Crt;

var y,g: array [1..10] of real;

k,n: integer;

begin clrscr;

n:=0; {Спочатку кількість елементів у g = 0}

for k:=1 to 10 do

Begin

y[k]:=ln(k)–3;

if y[k]<0 then {Перевіримо чи елемент від'ємний}

Begin

n:=n+1; {Збільшимо кількість елементів вектора g }

g[n]:= y[k]; {Знайдемо n-ий елемент}

end;

writeln ('y(', k, ')=', y[k]:7:2);

end;

if n=0 then writeln ('Масив у від''ємних елементів не має')

Else

for k:=1 to n do

writeln ('g[', k, ']=', g[k]:7:2); {Виведемо масив g }

Readln

End.

 

2. Двовимірні масиви (матриці). Елементи двовимірного масиву (дані можуть бути подані у вигляді таблиці-матриці) визначаються іменем масиву та двома індексами: перший індекс означає номер рядка, а другий — номер стовпця, на перетині яких стоїть елемент, наприклад р[1,2], p[i,j].

Загальний вигляд конструкції опису типу матриці такий:

TYPE <назва типу>=array [<розмір>, <розмір>] of<назва базового типу>;

можна і так:

<список змінних>:array [<розмір>,<розмір>] of<назва базового типу>;

Розглянемо приклади оголошення масиву-константи bal, що має 2 рядки і 4 стовпці елементів, деякого масиву doba, який міститиме 24·60 елементів цілого типу, двовимірного масиву р розміру 9 на 9 (тут буде 9·9=81 елемент).

const bal: array [1..2, 1..4] of integer=((4,3,5,3), (4,4,5,3));

var doba: array [0..23] of array [0..59] of integer;

const n = 9;

var p: array [1..n, 1..n] of integer;

 

Тут bal[1,1]=4, bal[1,2]=3, …, bal[2,3]=5, bal[2,4]=3. Значення елементам масивів doba i p можна надати командою присвоєння двома способами,наприклад, так: doba[16][30]:=5, doba[16,30]:=5.

Задача 3. Скласти програму для занесення в двовимірний масив р таблиці множення двох чисел і виведення масиву на екран.

program Pifagor;

uses Crt;

const n = 9;

var p: array [1..n, 1..n] of integer; i, j: integer;

begin clrscr;

for i:= 1 to n do begin

for j:= 1 to n do begin

p[i, j]:= i * j;

write (p[i, j]: 6) {Зверніть увагу на команди виведення масиву}

end; {у вигляді таблиці}

Writeln

end;

Readln; end.

Задача 4. Кондитерська фабрика для виготовлення п'яти сортів цукерок використовує п'ять видів сировини. Нехай норми затрат aij кожного виду сировини і на виробництво 1т цукерок сорту j задані формулою aij = 2|Sin(i)|+j,. Вивести на екран таблицю затрат сировини (тобто масив а). Визначити для якого сорту цукерок (imin) потрібно найменше сировини (min) третього виду.

program Fabryka;

uses Crt;

type vytraty = array [1..5, 1..5] of real;

var i,j,imin: integer; min: real; a:vytraty;

begin clrscr;

writeln (' Вид сировини');

writeln (' 1 2 3 4 5');

for i:=1 to 5 do {Утворимо таблицю затрат}

Begin

write (i, ' сорт');

for j:=1 to 5 do

Begin

a[i,j]:=2*abs(sin(i)) +j;

write (a[i,j]:7:2); {Роздрукуємо елементи і-го рядка}

end;

writeln {Перейдемо на новий рядок}

end;

imin:=1;

min:=a[1;3]; {Припустимо, що найменше сировини третього}

for i:=2 to 5 do {виду потрібно для цукерок першого сорту}

if a[i,3]<min then

Begin

min:=a[i,3]; imin:=i; {Визначимо шуканий сорт цукерок}

end;

writeln ('Найменше сировини третього виду ');

writeln ('потрібно для цукерок ', imin, ' сорту');

Readln; end.

Зауваження. Нехай задана деяка матриця ai,j,. Тоді вирази i = j, i < j та i > j визначають відповідно елементи головної діагоналі, елементи над та під головною діагоналлю цієї матриці.


Рядки

1. Рядки (string). Дане типу рядок — це послідовність довільних символів (тобто елементів типу char). Сталі типу рядок записують за допомогою двох штрих-символів, які охоплюють текст. Рядок може містити від 0 до 255 символів. Наприклад, 'Україна', 'Львівська політехніка', '' – порожній рядок нульової довжини, ' ' – рядок, що містить один символ-пропуск.

Змінну типу рядок оголошують за допомогою слова string так:

var <змінна>: string[n];

де n –довжина рядка, n<256. Довжину рядка можна не зазначати.

Приклад.

const slovo=’University’;

var fraza1: string[45]; fraza2: string;

Над змінними типу рядок визначені операції з’єднання (+) та порівняння (<, <=, >, >=, =, <>). Порівняння двох рядків здійснюється зліва направо до перших різних символів, причому 'A'<'B', 'B'<'C' тощо. “Більшим” вважається символ, який розташований в алфавіті далі. Числовий код символу дає функція ord, наприклад, ord('B')=66, ord('A')=65. Зворотну дію виконує функція chr: chr(66) дає 'B'.

Приклад. Нехай t1='New', t2=' Year'. Тоді з'єднанням цих рядків буде s:=t1+t2 (s матиме значення 'New Year'). Тут s > t1.

Приклад. Вивести на екран малі літери латинського алфавіту та їхні коди можна так: for v:= 'a' to 'z' do writeln(v, ord(v):5).

 

2. Функції та процедури для дій з рядками. Над даними типу рядок визначені такі стандартні функції:

length(<рядок>) — визначає кількість символів у рядку; copy(r, m, n) — дає n символів рядка r, починаючи з символу з номером m; concat(r1, r2,..., rn) — з'єднує рядки r1,..., rn в один рядок; pos(r1, r2) — визначає номер символу, з якого починається входження рядкаr1 у рядок r2.

та процедури:

insert(r1, <змінна>, n) — вставляє рядок r1 у рядок, заданий змінною, починаючи з позиції n; delete(<змінна>, m, n) — вилучає n символів з рядка, заданого змінною, починаючи з позиції m; str(<число>, <змінна>) — переводить числове дане в дане типу рядок;

де зазначена змінна посилає в процедуру вхідне дане типу рядок і отримує назад інший рядок – результат виконання процедури.

Приклад. Нехай змінна Lviv має значення 'Львівська політехніка'. Розглянемо приклади функцій та їхні значення:

ФункціяЗначення

length (Lviv) 21;

copy (Lviv, 15, 11) техніка;

concat (Lviv,' – 2000') Львівська політехніка – 2000;

pos ('т', Lviv) 15.

Наступні процедури нададуть змінній Lviv таких значень:

Процедура Значення змінної Lviv

insert ('НУ ', Lviv, 1) 'НУ Львівська політехніка'

delete (Lviv, 6, 16) 'Львів'

str (2000, Lviv) '2000'

val ('1256', Lviv1, Ozn) Lviv1=1256, Ozn=0

 

Є два способи опрацювання даних типу string. Перший — можна опрацьовувати весь рядок як єдине ціле, застосовуючи до нього функції та процедури, другий — можна розглядати рядок як масив, складений з елементів-символів, і опрацьовувати його за правилами роботи з елементами масиву.

Приклад. Деякі значення змінним fraza1 та fraza2 з попереднього прикладу можна надати, а потім вивести тексти на екран так:

fraza1:=’Ви любите канікули?’;

for i:=1 to 19 do read(fraza2[i]);{Вводимо текст з клавіатури}

writeln(fraza1); writeln(fraza2).

 

Задача 1. Кодування інформації. Вилучити з фрази а пропуски, коми і крапки, інші символи продублювати. Вивести результат.

program MyCode;

uses Crt;

var a, b, c: string; i: integer;

begin

clrscr;

write('Введіть текст: ');

readln(a); {Вводимо будь-яку фразу}

b:= '';

for i:= 1 to Length(a) do

begin

c:= Copy(a, i, 1); {Зверніть увагу на коментар унизу:}

if (c <> ',') and (c <>'.') and (c <>' ') { або так: c:= a[i]; }

then b:= b + c + c

end;

writeln(b);

readln

end.

 

Задача 2. Скласти програму, яка скрізь у заданому тексті mytext замінить деяке слово іншим словом такої ж довжини (word1 на word2).

program FindAndChange;

uses Crt;

var mytext, word1,word2: string; i,k: integer;

begin

clrscr;

write('Введіть текст: '); readln(mytext);

write('Введіть шукане слово: '); readln(word1);

write('Введіть інше слово: '); readln(word2);

k:= length(word1);

for i:= 1 to length(mytext) - k do

if copy(mytext, i, k) = word1 then

begin

delete(mytext, i, k);

insert(word2, mytext, i)

end;

writeln(mytext);

readln

end.

 

Задача 3. Нехай задано рядок 'Я люблю інформатику'. Визначити довжину рядка. Вивести на екран друге слово цього рядка.

program Ryadok;

uses Crt;

const r1: string = 'Я люблю інформатику';

var i,k,m,n1,n2: integer;

begin

clrscr;

m:=0;

k:=length(r1); {Визначаємо довжину рядка}

writeln('Довжина рядка k=', k);

for i:=1 to k do {Переглядаємо всі символи рядка}

if r1[i]=' ' then {Шукаємо пропуск}

begin

m:=m+1;

if m=1 then n1:=i; {Визначаємо номер першого та другого пропусків}

if m=2 then n2:=i

end;

for i:=n1+1 to n2–1 do write(r1[i]); {Виводимо слово між двома пропусками}

readln

end.


Графіка

1. Графічний режим. Графічний екран дисплея складається з точок, які можна засвічувати певним кольором чи гасити, у результаті чого на екрані утворюється деяке зображення. Точки називаються пікселями. Кількість точок на екрані може бути різною, що залежить від якості екрана. Розглянемо екран, який має 640 точок у горизонтальному (x) напрямку і 480 у вертикальному (y). Початок відліку точок є у лівому верхньому куті екрана. Кожна точка характеризується двома координатами (x,y). Приклади розташування на екрані деяких точок показані на рис. 3.

Рис. 3. Координати точок на графічному екрані 640х480

Програми, що виконують графічні побудови, переважно є лінійними і складаються з викликів стандартних графічних процедур та функцій, зібраних у модулі Graph.tpu.

Сам модуль може бути в бiблiотеці Turbo.tpl або в деякому каталозі на диску. В останньому випадку модуль треба приєднати командою uses на початку програми. Потрібний також файл egavga.bgi — драйвер для VGA адаптера чи файл cga.bgi для відповідного CGA адаптера монітора тощо.

Графічний режим спочатку треба задати. Це виконують так:

<розділи описів та оголошень конкретної програми>; var driver, mode: integer; {Для характеристик дисплея} begin driver:= detect; {detect - стандартна стала} initgraph (driver, mode, ''); {Задання графічного режиму} if graphresult < > 0 then begin writeln('графічний режим задати не вдалося'); halt {Стоп} end; <текст конкретної програми з графічними командами> end.

 


2. Процедури і функції для графічних побудов. Розглянемо процедури модуля Graph, призначені для графічних побудов.

initgraph (driver, mode, <шлях до драйвера>) — задає графічний режим. Шляхдо драйвера зазначають (у лапках), якщо він не є в тому ж каталозі, що й файл turbo.exe; detectgraph (<драйвер>, <режим>) — повертає значення характеристикдисплея; setcolor(<колір>) — задає колір майбутнього зображення; setbkcolor (<колір>) — задає колір тла; putpixel (x, y, <колір>) — висвітлює точку (x,y) заданим кольором; line (x1, y1, x2, y2) — рисує лінію між двома точками; lineto (x, y) — рисує лінію від поточної точки до точки (x,y); linerel(dx, dy) — рисує лінію від поточної точки з заданими приростами; rectangle (x1, y1, x2, y2) — рисує прямокутник з заданими координатами діагонально протилежних вершин (лівої верхньої та правої нижньої); setviewport (x1, y1, x2, y2, true) — задає координати нового графічного вікна. Логічна стала true задає режим відсікання зображення, яке виходитиме за межівікна; bar (x1, y1, x2, y2) — рисує зафарбований прямокутник; bar3d(x1, y1, x2, y2, <об'ємна глибина>, true) — рисує паралелепіпед; circle (x, y, R) — рисує коло з радіусом R і центром у (x,y); arc(x, y, <початковий кут>, <кінцевий кут>, <радіус>) — рисує дугу; pieslice (x, y, <початковий кут>, <кінцевий кут>, <радіус>) — рисує зафарбований сектор; ellipse (x, y, <початковий кут>, <кінцевий кут>, <горизонт. радіус>, <вертик.радіус>) — рисує еліпс чи дугу еліпса; setfillstyle(<заповнення>, <колір>) — задає спосіб заповнення замкнутоїобласті залежно від значення параметра заповнення: 0 — заповнення кольоромфону, 1 — суцільне заповнення, 2 — заповнення товстими горизонтальнимилініями, 3 — заповнення нахиленими лініями,..., 10 — заповнення точками,11—щільне заповнення точками; floodfill (x, y, <колір межі>) — заповнює замкнену область, що містить точку(x,y); closegraph — закриває графічний режим; outtext(<текст>) — виводить заданий текст з поточної позиції; outtextxy(x, y, <текст>) — виводить текст у заданому місці; settextstyle(<шрифт>, <напрям>, <розмір>) — задає вигляд символів,напрямок виведення: 0 — горизонтально чи 1 — вертикально, і розміри символів: 1,2, 3.

Розглянемо деякі функції модуля Graph:

graphresult — повертає код помилки, якщо неможливо задати графічний режим, і 0 — у разі задання; getmaxx— повертає значення розміру екрана уздовж осі 0X; getmaxy— повертає значення розміру екрана уздовж осі 0Y; getcolor — повертає значення поточного кольору; getcolor(x,y) — повертає значення кольору точки (x,y); getx, gety — повертають координати поточного пікселя.

 

  1. Кольори. Кольори задають числами або англійськими назвами:
black=0 – чорний; blue=1 – синій; green=2 – зелений; cyan=3 – блакитний; red=4 – червоний; magenta=5 – фіолетовий; brown=6 – коричневий; lightgray=7 – світло-сірий; darkgray=8 – темно-сірий; lightblue=9 – яскраво-синій; lightgreen=10 – яскраво-зелений; lightcyan=11 – яскраво-блакитн.; lightred=12 – яскраво-червоний; lightmagenta=13 – яскраво-фіол.; yellow=14 – жовтий; white=15 – білий.

 

Задача 1. Нарисувати різними кольорами десять концентричних кіл, які мають спільний центр по середині екрана, тобто в точці з графічними координатами (320; 240), і описати навколо кіл червоний прямокутник.

program Circle10;

uses Crt, Graph;

var driver, mode, r: integer;

begin clrscr;

driver:= detect;

initgraph(driver, mode, '');

r:= 10; {Радіус першого кола 10 пікселів}

while r <= 100 do

begin

setcolor(r div 10);

circle(320, 240, r);

r:= r + 10

end;

setcolor(red);

rectangle(220, 140, 420,340); readln

end.

Задача 2. Нарисувати емблему. У верхній лівій частині графічного екрана на чорному фоні нарисувати блакитний квадрат, а в ньому – чорне коло, зафарбоване жовтим кольором. У центрі емблеми чорними літерами написати слово “Льотниче”.

program Emblema;

uses Crt, Graph;

var driver, mode, i, x1, y1: integer; x, y: real;

begin clrscr;

driver:=detect;

initgraph(driver,mode,'');

setbkcolor(0);

setcolor(3);

rectangle(100,0,300,200);

setfillstyle(1,3);

floodfill(200,100,3);

setcolor(14);

circle(200,100,100);

setfillstyle(1,14);

floodfill(200,100,14);

setcolor(0);

circle(200,100,100);

settextstyle(0,0,3);

outtextxy(135,95, 'Льотниче'); readln

end.

Задача 3. Нарисувати графік функції y=2sin(2x)+1 на проміжку [0; 2p], табулюючи функцію з кроком h=0,1. У результаті експериментів, міняючи значення амплітуди в пікселях (за допомогою множника М), зобразити графік на екрані якнайкраще.

program GrafikSin;

uses Crt, Graph;

const a=0; b=2*pi; h=0.1; h1=5; x0=60; y0=240; M=50;

var driver, mode,x1,y1:integer; x,y:real;

function f(x:real):real;

begin

f:=2*sin(2*x)+1

end;

begin clrscr;

driver:= detect; initgraph(driver,mode,'');

setcolor(14); setbkcolor(1);

line(20,y0,600,y0); line (x0,440,x0,20); {Координатні осі}

x:=a; x1:= x0+trunc(M*x); {x,y – математичні координати}

y:=f(x); y1:=y0-trunc(M*y); {x1,y1 – графічні координати}

moveto(x1,y1);setcolor(15);

while x<=b do begin

y:= f(x); y1:=y0-trunc(M*y); lineto(x1,y1);

x1:=x1+h1;x:=x+h

end;

settextstyle(0,0,1);

outtextxy(60,245,'0');outtextxy(360,245,'6.3');

settextstyle(0,0,2);

outtextxy(200,380,'Графік функції y=2sin2x+1');readln

end.


ПРИКЛАДИ



Поделиться:


Последнее изменение этой страницы: 2016-04-07; просмотров: 978; Нарушение авторского права страницы; Мы поможем в написании вашей работы!

infopedia.su Все материалы представленные на сайте исключительно с целью ознакомления читателями и не преследуют коммерческих целей или нарушение авторских прав. Обратная связь - 3.236.19.251 (0.417 с.)