Глава 16. Строки, файлы, обработка ошибок

В этой главе я собрал совершенно необходимые, но разнокалиберные вещи, которые по тематике не подходили к другим главам.

Строки

Со строковым типом Stringмы познакомились в 4.7. Какие интересные задачи связаны с работой со строками? Шифровка-дешифровка информации. Поиск в длинном тексте (например, в словаре или в инструкции по игре) нужного слова, которое просто так, глазами, искать очень долго. Автоматическое исправление орфографических ошибок в диктанте по русскому языку. И так далее.

Для решения этих задач мы должны уметь "влезать внутрь строк", то есть анализировать и преобразовывать строки. Visual Basic предоставляет для этого богатый набор функций. Вот некоторые из них:

Функция	Результат	Пояснение
"Мото" +"роллер"	Мотороллер	Операция + над строками просто соединяет строки в одну. Visual Basic может ее спутать со сложением чисел
"Мото" &"рол" & "лер"	Мотороллер	Операция & тоже соединяет строки в одну. Ее рекомендуется всегда применять вместо +, так как со сложением ее не спутаешь
Len("Чук и Гек")		Длина строки, включая пробелы
Mid("Астроном", 3, 4)	трон	Часть строки длиной 4, начиная с 3-го символа
Mid("Чук и Гек", 5, 1)	и	5-й символ в строке

При помощи функцииMid вы можете добраться до каждой буквы в тексте. Следующий фрагмент распечатывает в столбик слово "Телепортация":

s = "Телепортация"

For i = 1 To Len(s)

Debug.Print Mid(s, i, 1) 'Это i-я буква в строке

Next

 

Следующая функция позволяет искать в тексте нужное слово:

InStr("Астроном", "трон")		Позиция (номер символа), начиная с которой строка "трон" находится в строке "Астроном"
InStr ("Астроном", "Трон")		Строка "Трон" не найдена в строке "Астроном"
Left("Победа", 2)	По	2 левых символа в строке
Right("Победа", 3)	еда	3 правых символа в строке
Ucase("астРОнОм")	АСТРОНОМ	Все символы строки переводятся в верхний регистр
Lcase("астРОнОм")	астроном	Все символы строки переводятся в нижний регистр

 

В 2.5 (Калькулятор) жизнь заставила нас познакомиться с функцией Val, которая преобразует строку в число, а в 4.10 (Переменные) - с функцией Str, которая преобразует число в строку. Напомним их вам:

Val("20 груш и 8 яблок")		Функция читает строку слева направо, пока не натолкнется на символы, никакого отношения к числам не имеющие
Val (" - 1 0груш")	-10	На пробелы при этом внимание не обращается
3 * Val("2" & "0")		Выражение "2" & "0" равняется строке "20", ну а Val ("20") равняется числу 20
Str(5 * 5)		Число 25 преобразуется в строку "25". Хотя, надо сказать, что Visual Basic при работе с данными во многих случаях сам, без всякого вмешательства, услужливо преобразовывает данные к удобному с его точки зрения типу.

 

Когда мы вводим текст в текстовое окно, мы часто не замечаем, что лишний раз нажали на клавишу пробела, тем более, что лишние пробелы, особенно в самом начале и в самом конце строки, заметить трудно. Мы не всегда заботимся о том, чтобы избавиться от них. А зачем? А затем, что компьютер пробелы видит не хуже любой буквы и считает их полноправными символами. Мы склонны считать строки "Африка" и "Африка " вполне одинаковыми. Компьютер же не может позволить себе такой вольности, он прекрасно видит, что во второй строке в конце стоит пробел. Значит строки не равны и это может привести к неожиданным для нас результатам. Следующие три функции позволяют нам справиться с невнимательностью:

Функция	Результат	Пояснение
"Ж" & LTrim(" Бутевни матлны ") & "Ж"	ЖБутевни матлны Ж	Функция LTrim отсекает ведущие слева пробелы
"Ж" & RTrim(" Бутевни матлны ") & "Ж"	Ж Бутевни матлныЖ	Функция RTrim отсекает волочащиеся справа пробелы
"Ж" & Trim(" Бутевни матлны ") & "Ж"	ЖБутевни матлныЖ	Функция Trim отсекает пробелы и слева и справа

Таблица ASCII

Символы, используемые в работе с компьютерами, сведены в так называемую таблицу ASCII. У каждого из них есть порядковый номер в этой таблице. Его нам сообщает функция Asc. Функция же Chrнаоборот - по номеру сообщает символ:

Функция	Результат	Пояснение
Asc("Ы")		Буква Ы стоит в таблице ASCII под 219 номером
Chr(219)	Ы	Под 219 номером в таблице ASCII стоит буква Ы

Всего в таблице ASCII 256 символов, пронумерованных от 0 до 255. Вот фрагмент, распечатывающий эти символы, начиная с 32-го:

For i = 32 To 255

Debug.Print Chr(i);

Next

Вот результат работы фрагмента:

!"#$%&'()*+,-./0123456789:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\]^_`abcdefghijklmnopqrstuvwxyz

{|}~ЂЃ‚ѓ„…†‡?‰Љ‹ЊЌЋЏђ‘’“”•–—?™љ›њќћџ ЎўЈ¤Ґ¦§Ё©Є«­®Ї°±Ііґµ¶·ё№є»јЅѕї

АБВГДЕЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯабвгдежзийклмнопрстуфхцчшщъыьэюя

 

Задание 124: Определите без компьютера, что напечатает оператор Debug.Print Chr(Asc("Ю") + 1)?

Задание 125: "Детская шифровка". Среди детей встречается игра, заключающаяся в зашифровке своей речи “для секретности” за счет вставки в произносимые слова какого-нибудь звукосочетания, например, “быр”. Тогда вместо слова “корова” будет произнесено “кобырробырвабыр”. Составьте программу, которая распечатывает любую строку из 6 букв, после каждой второй буквы вставляя “быр”. Если получилось, то решите эту задачу для строки произвольной длины.

Задание 126: Давайте поставим задачу шифрования текста более серьезно. Имеется строка текста. Требуется написать программу, которая зашифровывала бы ее в другую строку. Способов шифровки вы можете придумать сколько угодно. Попробуйте такой – заменять каждый символ текста символом, следующим по порядку в алфавите (в таблице ASCII). Тогда слово кот превратится в слово лпу. Составьте, пожалуйста, и программу дешифровки. Когда вы познакомитесь с файлами, вы сможете уже зашифровывать и дешифровывать не отдельные строки, а целые тексты. В том числе и ваши программы.

Один из возможных путей программирования таких задач: Начните с того, что объявите массив, состоящий из строк длины 1, то есть, по сути, массив символов. Вот как это сделать: Dim s(20) As String * 1. Заполните массив символами исходной строки. Теперь вам будет удобней с ними работать. Придумайте, что делать с буквой "я". В ответе же эта задача решена другим, более коротким способом.

Файлы

Если вы играли в компьютерные игры, то наверняка сохранялись. А задумывались ли вы над тем, что значит сохраниться? Вы знаете, что в результате сохранения игра в следующий раз начинается с того места, где вы остановились раньше. А как компьютер помнит, где вы остановились? В каком месте компьютера хранится эта информация? В персональном компьютере два вида памяти - оперативная и на диске (смотри Приложение 1). Оперативная память стирается в момент выключения компьютера, а поскольку компьютер мы выключаем чуть ли не каждый день, то использовать ее для сохранения нельзя. Поэтому все, что нужно сохранить, компьютер запоминает на диске. Когда в следующий раз вы запускаете игру, то программа игры считывает с диска сохраненную информацию и с ее помощью позволяет вам продолжить игру с того места, где вы остановились. Какую именно информацию об игре нужно для этого сохранять, вам станет ясно позже.

Как книжка состоит из рассказов, так диск состоит из файлов. Файлов на диске множество. Каждая игра и вообще любая программа сохраняется в своем файле. Сколько игр, столько и файлов. Говорят, что когда происходит сохранение информации в файле, то информация выводится или записывается из оперативной памяти в файл, а когда игра или другая программа читает эту информацию из файла, то говорят, что информация вводится или загружается из файла в оперативную память.

Если вы еще не знакомы с понятием файла или папки, прочтите Приложение 2. Для определенности мы будем считать, что файл расположен именно на магнитном диске, хотя файл - достаточно общее понятие, которое может применяться к различным устройствам ввода, вывода и хранения информации.

В Visual Basic существует несколько типов файлов. Мы познакомимся с самым простым из них - текстовым файлом. Вам совершенно не обязательно знать, как физически устроен носитель, на который файл будет записываться. При работе с текстовым файлом удобно воображать, что носитель - не диск, состоящий из дорожек, а подобен листу бумаги или экрану монитора, файл же - это строки информации на этом листе или экране. Запись в файл и считывание из файла осуществляются магнитной головкой, которая движется по строкам файла строго последовательно, не пропуская ни строки, подобно авторучке, когда вы пишете письмо, или глазу, когда его читаете. Но у магнитной головки нет свободы глаза или авторучки, которые по вашему желанию могут "прыгать" по листу, как хотят. Головка движется строго последовательно, не пропуская ни символа, поэтому такие файлы еще называют файлами с последовательным доступом.

Данные в текстовых файлах могут быть числами, строками или иметь другой тип.

Сейчас на шести задачах мы научимся работать с текстовыми файлами.

 

Задача 1: Записать слово "Азия" и число 1998 на магнитный диск c: в текстовый файл с именем Filimon.txt, располагающийся в папке VB.

Решение: Прежде всего вы должны убедиться, что такая папка действительно существует по указанному адресу. Файла же там может и не быть. Затем придумаем файлу Filimon.txt номер, которым мы будем пользоваться в программе. Пусть это будет 1.

Прежде чем начать работать с файлом, он должен быть открыт. При этом компьютер выполняет определенные подготовительные действия для работы с файлом. Вот как выглядит оператор, открывающий текстовый файл для записи:

 

Оператор:	Open	"C:\VB\Filimon.txt"	For	Output	As	#1
Перевод:	Открыть файл	"C:\VB\Filimon.txt"	для	вывода	как	№1

 

Если файл раньше не существовал, то он создается. Если файл открывается для записи, то магнитная головка перемещается в начало файла. Это означает, как вы можете догадаться, что если в файле было раньше что-то записано, то все сотрется. Вот программа:

Private Sub Command1_Click()

Open "C:\VB\Filimon.txt" For Output As #1 'Открыть для записи файл Filimon.txt в папке VB диска C под номером 1

Write #1, "Азия" 'Записать в файл №1 строку "Азия"

Write #1, 1998 'Записать в файл №1 в следующую строку число 1998

Close #1 'Закрыть файл №1

End Sub

Вы видите, что собственно запись осуществляется оператором Write. После работы с файлом его нужно закрыть оператором Close.

Давайте убедимся, что все действительно правильно записалось. Для этого выйдем из Visual Basic в Windows, найдем нужную папку и обнаружим, что там действительно находится файл Filimon.txt. Чтобы заглянуть в него, щелкните по нему дважды мышкой, он откроется программой Notepad и вы увидите, что он содержит две строки:

"Азия"

Если вместо двух операторов Write вы напишете один:

Write #1, "Азия", 1998

то в файл будет записана одна строка:

"Азия",1998

Если вы не хотите стирать содержимое файла, а просто хотите дописать что-нибудь в его конец, то вместо слова Output в операторе Open нужно использовать слово Append.

 

Удобно держать текстовый файл, в который ваша программа сохраняет свои данные, в той же папке, где находятся файлы вашего проекта. В этом случае возникает проблема - при переносе папки с проектом в другое место диска изменяется ее адрес, а значит и адрес файла данных. В операторе же Open указан старый адрес. Visual Basic выдаст сообщение об ошибке. В этой ситуации нужно в операторе Open дать понять компьютеру, что файл находится именно в папке с файлами проекта. Делается это так:

Open App.Path & "\Filimon.txt" For …

App.Path - это адрес папки вашего проекта, где бы он ни путешествовал.

 

Информация в наш файл может записываться только по порядку, последовательно. Мы не можем записать что-то сперва в начало файла, потом в конец, потом в середину. То же самое относится и к считыванию, о котором сейчас пойдет речь.

 

Задача 2: В файле Filantrop.txt в папке проекта записаны следующие строки:

"Азия"

"Африка", 2000

….

Вывести третью строку на экран монитора.

Вот программа:

Private Sub Command3_Click()

Dim a1 As Integer 'Четыре переменные в оперативной памяти,

Dim a2 As String 'в которые будут загружены данные

Dim a3 As String 'из первых трех строк

Dim a4 As Integer 'файла

Open App.Path & "\Filantrop.txt" For Input As #1 'Открыть для чтения под номером 1 файл Filantrop.txt из папки проекта

Input #1, a1 'чтение 1-й строки

Input #1, a2 'чтение 2-й строки

Input #1, a3, a4 'чтение 3-й строки

Close #1 'Закрыть файл 1

Debug.Print a3, a4

End Sub

Вот результаты в окне Immediate:

Африка 2000

Вы видите, что собственно чтение осуществляется оператором Input. После работы с файлом его нужно закрыть оператором Close. Обратите внимание, что для того, чтобы добраться до третьей строки, нам пришлось "зря" прочитать первые две.

 

Задача 3: В предыдущей задаче мы еще до считывания знали, как располагаются по строкам и внутри строк данные в файле Filantrop.txt. Однако, нередки случаи, когда мы не имеем об этом представления. Все, что мы знаем, это то, что файл состоит из строк. Тем не менее, хочется прочитать данные из файла, чтобы хотя бы посмотреть на них. Для этого можно приказать Бэйсику загружать каждую строку файла, независимо от того, из каких данных она состоит, в переменную типа String. Вот программа, распечатывающая три первые строки файла Filantrop.txt:

Private Sub Command4_Click()

Dim s1 As String 'Три переменные в оперативной памяти,

Dim s2 As String 'в которые будут загружены три

Dim s3 As String 'первые строки файла

Open App.Path & "\Filantrop.txt" For Input As #1 'Открыть для чтения под номером 1 файл Filantrop.txt из папки проекта

Line Input #1, s1 'чтение очередной строки файла

Debug.Print s1

Line Input #1, s2 'чтение очередной строки файла

Debug.Print s2

Line Input #1, s3 'чтение очередной строки файла

Debug.Print s3

Close #1 'Закрыть файл 1

End Sub

Загрузку очередной строки в переменную типа String выполняет оператор Line Input. Вот результаты в окне Immediate:

"Азия"

"Африка", 2000

Вы видите, что кавычки и запятая не исчезли, как это было в распечатке задачи 2. Это потому, чтоLine Input не обращает внимания на символы, из которых состоит строка файла. Он просто загружает их подряд в строковую переменную. В нашем случае, например, строка s3 состоит из символов "Африка", 2000, включая кавычки и запятую.

 

Если вы хотите как-то изменить содержимое текстового файла на диске, то вам целесообразно полностью загрузить его в память, изменить его там, как вам надо, а затем то, что получилось, целиком записать обратно в файл.

Задача 4: Файл f состоит из 10 строк. Дописать в конец каждой строки восклицательный знак.

Программа:

Dim s(1 To 10) As String

Private Sub Command1_Click()

'Загружаем файл в память:

Open App.Path & "\f.txt" For Input As #1 'Открыть для чтения под номером 1 файл f.txt из папки проекта

For i = 1 To 10

Line Input #1, s(i) 'чтение очередной строки файла

Next

Close #1 'Закрыть файл 1

'Преобразовываем строки в памяти:

For i = 1 To 10

s(i) = s(i) & "!" 'Добавляем восклицательный знак в каждую строку

Next

'Записываем преобразованные строки в файл:

Open App.Path & "\f.txt" For Output As #1 'Открыть для записи под номером 1 файл f.txt из папки проекта

For i = 1 To 10

Print #1, s(i) 'Запись очередной строки в файл

Next

Close #1 'Закрыть файл 1

End Sub

Вы видите, что в этой программе запись осуществляется оператором Print, а не Write. Иначе бы строки в результирующем файле брались в кавычки, как это было в задаче 2.

Таким образом, оператор Print применяется для вывода не только на монитор, но и в файл.

 

Задача 5: Вам нужно прочесть все строки файла, а сколько строк в файле вы не знаете.

Ваши действия: В этом случае оператор цикла For не подойдет, так как там нужно указывать точное число строк. Хорошо бы Бэйсику можно было приказать: "Читай, пока файл не кончился". И такой приказ есть. В его основе лежит функция EOF (End of File), которая в процессе последовательного считывания файла все время "чувствует", кончился ли он, и если кончился, принимает значение True, иначе - False.

Упомянутый приказ реализуется фрагментом:

Do While Not EOF(1) 'Выполняй, пока НЕ наступил КОНЕЦ ФАЙЛА 1

Line Input #1, s(i)

i = i + 1

Loop

 

А теперь на примере примитивной задачи продемонстрируем, как программа может сохранять нужные ей данные, чтобы в следующий раз воспользоваться ими:

Задача 6: Пусть в файле Данные.txt записано число 10. После запуска программа должна раз в секунду печатать последовательные целые числа, начиная с числа, записанного в этом файле. Больше ничего делать ей не нужно. Понаблюдав некоторое время за печатью чисел, вы завершаете выполнение проекта. Вся соль задачи в том, чтобы при следующем запуске программа начала печатать не с 10, а с того числа, на котором завершился проект.

Ваши действия:

1. Вам необходимо сделать так, чтобы при запуске программы число считывалось из файла и счет начинался с него.

2. Вам необходимо сделать так, чтобы при завершении работы последнее из напечатанных чисел записывалось в файл на место десятки. Тогда в следующий раз счет сам собой начнется с него.

Создайте таймер. Настройте его интервал на 1 секунду.

Программа:

Dim Число As Integer

 

Private Sub Form_Load()

Open App.Path & "\Данные.txt" For Input As #1 'Открыть для чтения под номером 1 файл Данные.txt из папки проекта

Input #1, Число 'Чтение числа, с которого начать счет

Close #1 'Закрыть файл №1

End Sub

 

Private Sub Timer1_Timer() 'Процедура таймера, выполняемая раз в секунду

Debug.Print Число 'Печать числа

Число = Число + 1 'Получаем следующее число

End Sub

 

Private Sub Form_Unload(Cancel As Integer)

Open App.Path & "\Данные.txt" For Output As #1 'Открыть для записи под номером 1 файл Данные.txt из папки проекта

Write #1, Число 'Запись в файл числа, на котором закончен счет

Close #1 'Закрыть файл №1

End Sub

Здесь я использовал событие Form_Unload. Оно так же, как и событие Form_Terminate, наступает при завершении работы проекта нажатием на крестик в правом верхнем углу формы. Для нас между этими событиями нет разницы.

 

Кроме файлов с последовательным доступом существуют еще файлы с произвольным доступом. Информация в этих файлах записывается упорядоченно и регулярно, благодаря чему к ней возможен более гибкий и быстрый доступ. На них мы останавливаться не будем.

 

Задание 127: Создайте игру "Угадай число". Компьютер загадывает число из диапазона от 1 до миллиарда. Человек должен его отгадать. Причем за наименьшее число попыток. При каждой попытке компьютер печатает номер попытки, число, предложенное человеком, и подсказку - " мало " или " много ".

Поскольку даже у самых умных математиков на угадывание уйдет несколько десятков попыток, то в процессе угадывания может возникнуть желание сохраниться до лучших времен. При запуске игры в следующий раз компьютер должен спросить, начинать ли новую игру или продолжать старую. Если старую, то компьютер должен распечатать все то, что было распечатано в прошлый раз - все номера попыток, числа, подсказки.

Что еще можно делать с файлами

Visual Basic может выполнять над файлами и папками те же действия, что вы вручную выполняете в Проводнике Windows, а именно: создание папок, копирование, перемещение и уничтожение папок и файлов.

Пусть у вас на диске c в папке temp расположены папки 222, 333, 666, 999 и файл 1.txt.

Действия над файлами:

Оператор	Смысл
FileCopy"c:\temp\1.txt", "c:\temp\2.txt"	Оператор FileCopy копирует файлы. У него два параметра: первый - адрес копируемого файла, второй - адрес файла, в который производится копирование. В данном примере Файл 1.txt копируется в свою же папку под именем 2.txt
FileCopy "c:\temp\1.txt", "c:\temp\222\4.txt"	Файл 1.txt копируется в папку c:\temp\222 под именем 4.txt
Name"c:\temp\222\4.txt" As "c:\temp\222\5.txt"	Оператор Name As переименовывает и перемещает файлы и папки. Два его параметра имеют тот же смысл, что и у оператора FileCopy. В данном примере Файл 4.txt переименовывается в 5.txt и остается в своей папке.
Name "c:\temp\222\5.txt" As "c:\temp\5.txt"	Файл 5.txt перемещается в папку temp.
Kill"c:\temp\5.txt"	Оператор Kill уничтожает файл.

Действия над папками:

Name "c:\temp\333" As "c:\temp\444"	Папка 333 переименовывается в 444.
Name "c:\temp\666" As "c:\temp\222\666"	Папка 666 перемещается вместе со всем своим содержимым внутрь папки 222.
MkDir"c:\temp\888"	Создается пустая папка 888.
RmDir"c:\temp\888"	Уничтожается пустая папка 888.

В программировании широко используется понятие текущей папки. В данный момент времени текущая папка может быть только одна. Назначьте текущей папку, с файлами которой вы в данный момент работаете, и запись адресов в операторах существенно сократится. Например, работая в папке c:\temp\999, вы вместо того, чтобы все время писать операторы вида

FileCopy "c:\temp\999\22.txt", "c:\temp\999\44.txt"

один раз задаете текущую папку, вот так:

ChDir "c:\temp\999"

а затем уже все время пишете операторы такого вида:

FileCopy "22.txt", "44.txt"

Функция CurDir позволяет вам узнать, какая папка в настоящий момент является текущей. Для этого вам достаточно выполнить оператор Debug.Print CurDir.

Функция Shell

С помощью функции Shellвы можете, не выходя из проекта, запускать другие программы Windows. Например, строка

y = Shell ("C:\WINDOWS\Notepad.exe")

запускает стандартный текстовый редактор Windows - Блокнот (Notepad). В скобках вы должны указать адрес запускающего файла нужного вам приложения. Вместо адреса можно писать так называемую командную строку:

y = Shell ("C:\WINDOWS\Notepad.exe C:\Untitled.txt ")

Здесь Блокнот откроется с загруженным файлом C:\Untitled.txt.

Вы можете управлять видом окна, в котором откроется программа:

y = Shell ("C:\WINDOWS\Notepad.exe C:\Untitled.txt", vbMaximizedFocus)

Здесь окно будет развернуто на весь экран. Попробуйте другие константы: vbHide, vbNormalFocus, vbMinimizedFocus, vbNormalNoFocus, vbMinimizedNoFocus.