Массивы элементов управления

Задача: Выстроить вдоль нижней кромки формы на равных расстояниях друг от друга 20 автомобилей, вот так:

 

 

При нажатии кнопки эти автомобили должны прыгнуть вверх, вот так:

 

 

(самый левый остается на месте).

Трудности: Нам нужно поместить на форму 20 элементов управления Image и загрузить в них картинку автомобиля, что само по себе утомительно. Расположить их вручную на равных расстояниях тоже нелегко. Visual Basic дает возможность изящно преодолеть все эти трудности программным путем.

Ваши действия: Поместите на форму один объект Image и дайте ему имя imgАвто. Загрузите в него картинку автомобиля. Обратите внимание на его свойство Index. Оно пусто. Это значит, что данный объект пока не является элементом массива объектов. Заголовок у окна свойств такой: Properties - imgАвто. Придайте свойству Index какое-нибудь целое неотрицательное значение, например 1. Тут же заголовок у окна свойств меняется: Properties - imgАвто(1). Это значит, что данный объект стал элементом массива объектов. Пока в этом массиве один элемент - imgАвто(1).

Как создать остальные объекты массива? Можно вручную, скопировав его обычным образом, как я объснял в 11.3, но отвечая на вопрос - Yes. При этом Visual Basic будет придавать новым объектам индексы от 0 и выше. Но быстрее это сделать программным путем. Так, оператор

Load imgАвто(4)

создаст (загрузит) на форме новый объект imgАвто с индексом 4. Значит, если применить оператор в цикле, он загрузит нам все нужные объекты и создаст их массив. Безо всякого объявления. Вот программа:

Dim i As Integer

Dim N As Integer 'Количество объектов

______________________________________________________________________

Private Sub Form_Load()

N = 20

'Загружаем на форму и делаем видимыми все объекты массива, кроме первого (который и так уже загружен):

For i = 2 To N

Load imgАвто(i)

imgАвто(i).Visible = True

Next

'Помещаем на свои места все объекты массива:

For i = 1 To N

imgАвто(i).Top = Height - 1000

imgАвто(i).Left = 300 * i

Next

End Sub

______________________________________________________________________

Private Sub Command1_Click()

'Прыжок всех объектов:

For i = 1 To N

imgАвто(i).Top = imgАвто(i).Top - 50 * (i - 1)

Next

End Sub

Пояснения: Как обычно, первой выполняется процедура Form_Load, которая все создает и расставляет. Затем процедура Command1_Click выполняет прыжок автомобилей.

 

Вот более "правильный" вариант той же программы, использующий процедуры с параметрами:

Dim i As Integer

Dim N As Integer

______________________________________________________________________

Private Sub Form_Load()

N = 20

'Загружаем на форму и делаем видимыми все объекты, кроме первого (который и так уже загружен):

For i = 2 To N

Load imgАвто(i)

imgАвто(i).Visible = True

Next

'Помещаем на место все объекты:

For i = 1 To N

Поместить_автомобиль_на_место i

Next

End Sub

______________________________________________________________________

Private Sub Command1_Click()

'Прыжок всех автомобилей:

For i = 1 To N

Прыжок_автомобиля i

Next

End Sub

______________________________________________________________________

'Процедура, помещающая на место один объект из массива с индексом Номер_автомобиля:

Private Sub Поместить_автомобиль_на_место(Номер_автомобиля As Integer)

imgАвто(Номер_автомобиля).Top = Height - 1000

imgАвто(Номер_автомобиля).Left = 300 * Номер_автомобиля

End Sub

______________________________________________________________________

'Процедура прыжка одного объекта из массива с индексом Номер_автомобиля:

Private Sub Прыжок_автомобиля Прыжок_автомобиля (Номер_автомобиля As Integer)

imgАвто(Номер_автомобиля).Top = imgАвто(Номер_автомобиля).Top - 50 * (Номер_автомобиля - 1)

End Sub

В процедуре Прыжок_автомобиля вы можете задавать разным автомобилям разное поведение. Например:

If Номер_автомобиля = 8 Then imgАвто(Номер_автомобиля).Top = 1000

If Номер_автомобиля = 14 Then imgАвто(Номер_автомобиля).Visible = False

 

Чтобы удалить (выгрузить) 4-й объект с формы, применяем оператор Unload imgАвто(4).

 

Обратите внимание, что теперь, работая в окне кода и пытаясь получить заготовку процедуры для обработки события, принадлежащего автомобилю, вы получите ее с параметром Index, значение которого равно индексу автомобиля, с которым происходит событие, в массиве. Это позволяет вам задавать разную реакцию автомобилей на одно и то же событие. Например, следующая процедура

Private Sub imgАвто_Click(Index As Integer)

If Index = 2 Then imgАвто(Index).Top = imgАвто(Index).Top + 200 Else imgАвто(Index).Visible = False

End Sub

позволяет вам превращать любой автомобиль щелчком мыши в невидимку, а 2-й автомобиль вместо этого отскакивает.

 

Глава 14. Разные звери в одном ковчеге

В предыдущей главе я рассматривал массивы - структуры, состоящие из многих данных и объектов. В этой главе я продолжу рассматривать сложные структуры данных и объектов. Но если массивы - это одинаковые солдатики, стоящие стройными рядами в своих строгих батальонах, то те структуры, что мы рассмотрим в этой главе, больше напоминают натюрморт.

Тип Variant

Массив - это набор элементов. Если вы объявили массив некоторого типа, то он обязан состоять из элементов только этого типа. Например, каждый из десяти элементов массива, объявленного как

Dim a(1 To 10) As Integer

обязан быть целым числом. Ни один из них не имеет права быть строкой или дробным числом.

Имеется целый ряд задач, где хотелось бы, чтобы элементы в наборе имели разный тип. Этого можно достичь, если вообще не объявлять тип массива:

Dim a(1 To 3)

Private Sub Command1_Click()

a(1) = 32

a(2) = "кошка"

a(3) = #8:56:00 AM#

End Sub

В этом случае Visual Basic считает, что массив объявлен по умолчанию специальным типом Variant. Это тип-хамелеон. Он не возражает, если объявленная им переменная будет иметь значение любого типа. Он присматривает, чтобы выполнение программы при этом проходило по возможности гладко и без неприятностей для программиста.

Вместо Dim a(1 To 3) можно было прямо написать Dim a(1 To 3) As Variant.

Еще один пример всеядности Variant (здесь я объявлю этим типом не массив, а переменную):

Dim b As Variant 'можно было просто написать Dim b

Private Sub Command1_Click()

b = 77

b = "кот"

End Sub

 

Итак, если переменная не объявлена или объявлена без указания типа, Visual Basic считает ее принадлежащей типу Variant. Какой толк от этого типа? Иногда бывает так, что соблюдая приличия и объявляя тип каждой переменной, мы наталкиваемся во время выполнения программы на сообщение об ошибке Type mismatch (несовпадение типов). Это значит, что выполняя операции над данными разных типов и преобразовывая один в другой, Visual Basic не захотел преступать строгие рамки безопасности и приличий и потерпел крах. Не всегда у начинающего программиста хватает знаний, чтобы разобраться в причинах краха. В этом случае, если вы любите риск, объявите все данные одним типом - Variant или вообще не указывайте тип. Теперь вероятность сообщений об ошибке снизится, хотя несколько увеличится вероятность получения недостоверного результата.

Вернемся к нашему желанию иметь набор из элементов разных типов. Программисты не хотят для этого использовать массивы типа Variant. Они используют для этого так называемый пользовательский тип данных.

Пользовательский тип данных

В Паскале пользовательскому типу данныхсоответствуют записи, в языке Си - структуры. Рассмотрим простейший пример пользовательского типа:

Вы хотите занести в компьютер информацию о ваших любимых компьютерных играх, чтобы затем как-то ее анализировать, например, определить, какая игра занимает самое большое место на диске. Для простоты ограничим информацию об игре тремя элементами:

· Название игры

· Сколько места игра занимает на диске (в мегабайтах)

· Хорошая или плохая графика у игры (ваша оценка)

Также для экономии места ограничимся двумя играми. Ваша программа должна будет занести в память информацию об обеих играх, а затем выполнить три задания:

· Распечатать название первой игры

· Определить, сколько места займут на диске обе игры вместе

· Ответить, хороша или плоха графика у второй игры

Ваши действия: Для начала нужно создать пользовательский тип данных для размещения информации об одной игре. Нам уже приходилось конструировать перечислимый тип (см.11.3). Здесь действуем аналогично - придумываем новому типу имя (типИгра) и пишем:

Private Type типИгра

Название As String

Объем As Integer

Графика_хорошая As Boolean

End Type

Тип определен. (Объяснение слова Private отложим на будущее). Теперь Visual Basic знает, сколько места в памяти занимает информация об игре и какая у нее структура. Можно отводить место в памяти:

Dim Игра1 As типИгра

Dim Игра2 As типИгра

Вот полный текст программы:

'Создаем пользовательский тип:

Private Type типИгра

Название As String

Объем As Integer

Графика_хорошая As Boolean

End Type

'Отводим в памяти место под информацию о двух играх:

Dim Игра1 As типИгра

Dim Игра2 As типИгра

____________________________________________________________________

Private Sub Form_Load()

'Заносим в память компьютера информацию об играх:

Игра1.Название = "StarC": Игра2.Название = "Heroes III"

Игра1.Объем = 90: Игра2.Объем = 200

Игра1.Графика_хорошая = False: Игра2.Графика_хорошая = True

'Выполняем 1 задание:

Debug.Print Игра1.Название

'Выполняем 2 задание:

Debug.Print Игра1.Объем + Игра2.Объем

'Выполняем 3 задание:

If Игра2.Графика_хорошая Then Debug.Print "Хорошая графика" Else Debug.Print "Плохая графика"

End Sub

Обратите внимание, что имя элемента отделяется от имени переменной точкой подобно тому, как название свойства объекта отделяется точкой от имени объекта.

Выстроенную подобным образом в памяти информацию о чем-либо часто называют базой данных. Всю информацию об одной переменной (в нашем случае об одной игре) называют записью в этой базе данных. Программу, которая извлекает информацию из базы данных, сортирует записи и производит другую обработку информации в базе данных, называют системой управления базой данных. В нашем примере роль системы управления базой данных играет процедура Form_Load.

 

Элементы пользовательского типа могут иметь любой известный вам тип, в том числе быть массивом или пользовательским типом. Пусть вы хотите дополнить информацию об игре именами персонажей игры (не более 20). Вот каким массивом дополнится определение типа:

Private Type типИгра

Название As String

Объем As Integer

Графика_хорошая As Boolean

Персонаж(1 To 20) As String

End Type

Теперь можно использовать такие операторы:

Игра2.Персонаж(4) = "Криган"

Игра1.Персонаж(12) = "Fenix"

Debug.Print Игра1.Персонаж(10)

 

Усложним задание: Вы хотите создать базу данных о 30 играх. Для этого достаточно вместо объявлений

Dim Игра1 As типИгра

Dim Игра2 As типИгра

объявить массив: