Арсенид-галлиевый полевой транзистор с каналом n-типа

Арсенид-галлиевый полевой транзистор с управляющим p-n переходом и каналом n-типа, а также его модель описываются предложениями:

 

Вххх <узел стока> <узел затвора> <узел истока> <имя модели>

+ [(коэффициент кратности Area)]

.model <имя модели> gasfet(параметры)

 

Рис. 57. Подключение GaAs транзистора

 

Таблица 5. Параметры математической модели GaAs транзистора

Параметр	Описание	Значение по умолчанию	Единица измерения
LEVEL	Тип модели: 1 — модель Куртиса, 2 — модель Рэйтеона		—
VTO	Пороговое напряжение	-2,5	В
VBI	Контактная разность потенциалов	1,0	В
ALPHA	Константа, определяющая ток Idrain	2,0	1/В
В	Параметр легирования (для LEVEL = 2)	0,3	В-'
BETA	Коэффициент пропорциональности в выражении для тока стока	0,1	А/В^:
LAMBDA	Коэффициент модуляции длины канала		1/В
RG	Объемное сопротивление затвора		Ом
RD	Объемное сопротивление стока		Ом
RS	Объемное сопротивление истока		Ом
CGD	Емкость перехода затвор — сток при нулевом смещении		Ф
CGS	Емкость перехода затвор — исток при нулевом смещении		Ф
CDS	Емкость перехода сток — исток при нулевом смещении		Ф
IS	Ток насыщения р-n перехода (диода Шотки)	10^-14	А
TAU	Время переноса носителей заряда		c
М	Коэффициент, учитывающий плавность перехода	0,5	—
N	Коэффициент неидеальности		—
FC	Коэффициент нелинейности барьерной емкости прямосмещенного перехода	0,5	—
KF	Коэффициент, определяющий спектральную плотность фликкер-шума		—
AF	Показатель степени, определяющий зависимость спектральной плотности фликкер-шума от тока через переход		—

 

Директивы управления заданием

 

Директивы управления заданием (команды) начинаются с символа '.' (точка)

 

Расчет цепи по постоянному току (рабочая точка схемы).

Режим по постоянному току рассчитывается всегда перед выполнением всех видов анализа без указания специальных команд. Полная информация о режиме по постоянному току выводится в выходной файл результатов (файл, имеющий расширение.OUT) при задании команды:

 

.OP

 

Расчет цепи по постоянному току в зависимости от изменения входного напряжения или тока.

 

.DC,<имя> <min> <max> <step>

<имя> - имя изменяемой переменной (имя источника тока или напряжения)

<min> - начальное значение,

<max> - конечное значение,

<step> - шаг изменения

 

Пример. Входное напряжение Vin изменяется от 0 до 5В с шагом 0.1В:

.DC Vin 0V 5V 0.1V

 

Пример. Входной ток I1 изменяется от 0 до 1мА с шагом 10 мкА:

.DC I1 0mA 1mA 10UA

 

Для вывода рассчитанных характеристик в выходной файл (с расширением.OUT) в табличном виде используется команда:

 

.PRINT DC <список_переменных>

<список_переменных> - список выводимых переменных, в качестве которых могут выступать:

- напряжения в узлах схемы, перечисленные через один или несколько пробелов. Например, напряжения в узлах 2 и 11: V(2) V(11)

В этом случае команда.PRINT запишется:

.PRINT DC V(2) V(11)

- токи через элементы схемы. Например, ток через сопротивление Rload: I(Rload)

Команда.PRINT запишется:

.PRINT DC I(Rload)

В команде.PRINT можно одновременно указывать токи и напряжения. Например, напряжение в 10 узле и ток через R10:

.PRINT DC V(10) I(R10)

Вывод рассчитанных зависимостей в файл для последующего их просмотра с помощью программы PROBE осуществляется с помощью команды:

 

.PROBE <список_переменных>

<список_переменных> - список переменных, составленный аналогично команде PRINT. При указании команды.PROBE без списка в файл выводятся все напряжения в узлах и токи всех элементов.

 

Расчет цепи по переменному току (напряжению) при изменении частоты входного сигнала (частотный анализ).

 

.AC <вид_шага> <количество_точек> <fmin> <fmax>

<вид_шага> - "LIN" - линейный шаг по частоте

- "OCT" - логарифмический шаг по частоте (по октавам)

- "DEC" - логарифмический шаг по частоте (по декадам)

<количество_точек> - количество точек по частоте

<fmin> - начальное значение частоты (в герцах)

<fmax> - конечное значение частоты (в герцах)

 

Источник тока или напряжения, для которого меняется частота при расчете зависимости указывается при описании схемы (см. выше). Амплитуда сигнала указывается при описании источника.

Пример. Частота меняется в логарифмическом масштабе (в десять раз) от 10Гц до 10МГц, имеем 100 точек:

 

.AC DEC 100 10 10MEG

Для вывода рассчитанных характеристик в выходной файл (с расширением.OUT) в табличном виде используется команда:

 

.PRINT AC <список_переменных>

<список_переменных> - список выводимых переменных, в качестве которых могут выступать:

- напряжения в узлах схемы, перечисленные через один или несколько пробелов. Например, напряжения в узлах 2 и 11: V(2) V(11)

В этом случае команда.PRINT запишется:

 

.PRINT AC V(2) V(11)

("AC" означает, что выводятся зависимости для расчета зависимостей по постоянному току).

- токи через элементы схемы. Например, ток через сопротивление Rload: I(Rload)

Команда.PRINT запишется:

.PRINT AC I(Rload)

В команде.PRINT можно одновременно указывать токи и напряжения. Например, напряжение в 10 узле и ток через R10:

 

.PRINT AC V(10) I(R10)

Вывод рассчитанных зависимостей в файл для последующего их просмотра с помощью программы PROBE осуществляется с помощью команды:

 

.PROBE <список_переменных>

<список_переменных> - список переменных, составленный аналогично команде PRINT.

При указании команды.PROBE без списка в файл выводятся все напряжения в узлах и токи всех элементов.

- Расчет переходной характеристики цепи (во времени).

.TRAN <шаг_вывода> <время_окончания>

Источник изменяющегося тока или напряжения указывается при описании схемы (см. выше источники с PULSE).

Пример. Временной расчет с шагом 10 нсек и временем окончания 1 мксек

.TRAN 10nsec 1usec

-- Для вывода рассчитанных характеристик в выходной файл (с расширением.OUT) в табличном виде используется команда:

.PRINT TRAN <список_переменных>

список_переменных - список выводимых переменных, в качестве которых могут выступать:

- напряжения в узлах схемы, перечисленные через один или несколько пробелов. Например, напряжения в узлах 2 и 11: V(2) V(11)

В этом случае команда.PRINT запишется:

.PRINT TRAN V(2) V(11)

- токи через элементы схемы. Например, ток через сопротивление Rload: I(Rload)

Команда.PRINT запишется:

.PRINT TRAN I(Rload)

В команде.PRINT можно одновременно указывать токи и напряжения. Например, напряжение в 10 узле и ток через R10:

 

.PRINT TRAN V(10) I(R10)

Вывод рассчитанных зависимостей в файл для последующего их просмотра с помощью программы PROBE осуществляется с помощью команды:

 

.PROBE <список_переменных>

<список_переменных> - список переменных, составленный аналогично команде PRINT. При указании команды.PROBE без списка в файл выводятся все напряжения в узлах и токи всех элементов.

 

Примеры расчетов

 

Простейшие схемы

 

Расчет простого резистивного делителя

Рис. 58. Схема с пронумерованными узлами

 

Описание схемы для программы SPICE, файл circ1.cir, первая строка - заголовок:

 

Расчет резистивного делителя по постоянному току

R1 1 2 10

R2 2 0 5

V1 1 0 10V

.OP

.END

 

Пусть теперь необходимо для этой схемы рассчитать зависимость напряжения во 2 узле при изменении напряжения питания V1 от 0 до 50 Вольт с шагом 1В. Результаты необходимо вывести в файл для постпроцессора PROBE. В этом случае входной файл circ11.cir запишется:

 

Расчет резистивного делителя по постоянному току

R1 1 2 10

R2 2 0 5

V1 1 0 10V

.DC V1 0V 50V 1V

.PRINT DC V(1) V(2)

.PROBE

.END

 

Расчет частотной хаpактеристики простой RC-цепочки

 

Источник Е1 имеет синусоидальную форму сигнала, амплитуду 10 Вольт и частоту, изменяющуюся от 100Гц до 10МГц.

Рис. 59. Схема с пронумерованными узлами

 

Описание схемы для программы SPICE (файл circ1.cir):

 

Расчет RC-цепочки на синусоидальном сигнале

R1 1 2 10

С1 2 0 5UF

V1 1 0 AC 10V SIN(0 10V 1k)

.AC DEC 50 100 10MEG

.PLOT AC V(2)

.END

 

Анализ схемы включения транзистора с общим эмиттером

 

Расчет частотной характеристики схемы с ОЭ (рис. 60). Файл с описанием схемы:

 

Исследование схемы включения транзистора с ОЭ

R1 4 2 53k

R2 2 0 10k

R3 4 3 5k

R4 5 0 1k

RL 6 0 10k

C1 1 2 20UF

C2 3 6 20UF

C3 5 0 100UF

Q1 4 2 5 KT315

.model KT315 NPN(Is=1.e-13 Bf=50)

Vc 4 0 10V

Vin 1 0 DC 0V AC 0.02V SIN(0V 0.02V 1kHZ)

* расчет рабочей точки схемы

.OP

* расчет частотной характеристики

.AC DEC 5 10Hz 100kHz

.PROBE

.END

 

Рис. 60. Схема с пронумерованными узлами

 

Расчет ключа на биполярном транзисторе. (передаточная характеристика)

Файл с описанием схемы (рис. 61):

 

Ключ на биполярном транзисторе

R1 1 2 1k

Rk 4 3 1k

Vsupl 4 0 5V

Q1 3 2 0 kt317

.model KT317 NPN(Is=1.e-13 Bf=200 Br=5 Vaf=74 Var=30

+ Rb=230 Rc=15 Re=2 Cje=1pF Cjc=3pF Tf=12.e-9 Tr=7.e-8)

Vin 1 0 0V

* Расчет передаточной характеристики

* Входное напряжение меняется от 0 до 5 В с шагом 0.1 В

.DC Vin 0 5 0.1

.PROBE

.end

Рис. 61. Схема с пронумерованными узлами

 

 

Расчет ключа на биполярном транзисторе. (переходная характеристика, рис. 61)

 

Ключ на биполярном транзисторе

R1 1 2 1k

Rk 4 3 1k

Vsupl 4 0 5V

Q1 3 2 0 kt317

.model KT317 NPN(Is=1.e-13 Bf=200 Br=5 Vaf=74 Var=30

+ Rb=230 Rc=15 Re=2

+ Cje=1pF Cjc=3pF Tf=12.e-9 Tr=7.e-8)

Vin 1 0 PULSE(0V 5V 1us 10ns 10ns 100us 200us)

* расчет переходной характеристики, шаг вывода по времени 0.3 мкс,

* время моделирования 180 мкс

.TRAN 0.3us 180us

.PROBE

.end

 

Расчет выходных характеристик биполярного транзистора (лабораторная работа № 1)

 

Файл с описанием схемы:

 

Биполярный транзистор

Ib 0 1 30u

Vc 2 0 5V

Q1 2 1 0 kt317

.model KT317 NPN(Is=1.e-13 Bf=200 Br=5 Vaf=74 Var=30

+ Rb=230 Rc=15 Re=2 Cje=1pF Cjc=3pF Tf=12.e-9 Tr=7.e-8)

* Расчет выходных характеристик

* Ток базы принимает значения 30, 50, 70 мкА,

* Коллекторное напряжение меняется от 0 до 5 В с шагом 0.1 В

.DC Vc 0 5 0.1 Ib 30u 70u 20u

.PROBE

.end

 

Рис. 62. Схема с пронумерованными узлами

 

Расчет входных характеристик биполярного транзистора

 

Рис. 63. Схема с пронумерованными узлами

 

Файл с описанием схемы:

 

Биполярный транзистор

Vb 1 0 0.8V

Vc 2 0 3V

Q1 2 1 0 kt317

.model KT317 NPN(Is=1.e-13 Bf=200 Br=5 Vaf=74 Var=30

+ Rb=230 Rc=15 Re=2 Cje=1pF Cjc=3pF Tf=12.e-9 Tr=7.e-8)

* Расчет входных характеристик

* Напряжение базы меняется от 0 до 0.8 В с шагом 0.01 В

* Коллекторное напряжение равно 3В

.DC Vb 0 0.8 0.01

.PROBE

.end