Блоки генерации и удаления транзактов

GENERATE Tcp,Tм,Тн,Кт,Пр,Кп,Рп - блок генерации транзактов,

где Тср - средний интервал времени между последовательными транзактами;

Тм - разброс интервала времени относительно Тср;

Тн - время появления первого транзакта;

Кт - количество генерируемых транзактов;

Пр - приоритет транзактов;

Кп - количество параметров транзакта;

Рп - размер памяти для одного параметра.

TERMINATE Nз - блок удаления транзакта,

где Nз - уменьшение счетчика числа завершений на величину Nз.

Блоки занятия и освобождения приборов

SEIZE Ип - блок занятия прибора,

где Ип - имя прибора, подлежащего занятию транзактом.

RELEASE Ип - блок освобождения прибора,

где Ип - имя освобождаемого прибора.

ADVANCE Тср,Тм – блок задержки транзактов,

где параметры блока соответствуют параметрам блока GENERATE.

Пример 1

Процесс прохождения заявок, поступление которых подчиняется равномерному закону со средним значением 8 и промежутком [8-2, 8+2] единиц времени, а обработка - равномерному закону со средним 5 и отрезком [5-3,5+3], можно описать программой:

GENERATE 8,2; генерация транзактов

SEIZE DEV; занятие прибора

ADVANCE 5,3; задержка транзакта

RELEASE DEV; освобождение прибора

TERMINATE 1; уничтожение транзакта

START 10; запуск 10 транзактов

В процессе выполнения программы собирается стандартная статистическая информация, которая автоматически выводится на печать по окончании моделирования. Выходные статистические данные для блоков (BLOCK COUNTS) содержат текущее (CURRENT) и общее (TOTAL) показания счетчиков числа входов для каждого блока. В стандартном выводе статистической информации по устройствам представлена следующая информация: номер (имя) устройства (FACILITY), число входов или обслуживаний (ENTRIES), коэффициент использования устройства (UTIL.), среднее время одного обслуживания (AVE.TIME).

Блоки занятия и освобождения очереди

Транзакт помещается в очередь в том случае, когда некоторое устройство не в состоянии обслужить его немедленно (например, устройство занято, либо память переполнена). Статистические данные об очередях могут быть получены с помощью двух типов блоков:

QUEUE Ио,К - блок занятия очереди,

где Ио - имя очереди;

К - количество мест в очереди, занимаемое транзактом.

DEPART Ио,К - блок освобождения очереди,

где Ио - имя очереди;

К - количество мест в очереди, освобождаемое транзактом.

Блок QUEUE может быть помещен перед любым блоком модели, в котором может возникнуть задержка. Отметим, что очередь к занятому устройству автоматически организуется пакетом моделирования независимо от того, есть в программе блок QUEUE или нет. По очередям печатается информация: имя или номер очереди(QUEUE), максимальная длина очереди за время моделирования (MAX),минимальная длина очереди (CONT.), число входов в очередь (ENTRIES), число входов в очередь без последующего ожидания - нулевые входы (ENTRIES(0)), средняя длина очереди (AVE.CONT), среднее время пребывания в очереди (AVE.TIME), среднее время пребывания в очереди при учете только ненулевых входов(AVE.(0)).

Пример 2

В условиях предыдущей задачи необходимо получить статистические данные об очереди заявок, ожидающих обслуживание в приборе:

GENERATE 8,2

QUEUE SER

SEIZE DEV

DEPART SER

ADVANCE 5,3

RELEASE DEV

TERMINATE 1

START 10

Подготовка и выполнение моделирования в GPSS

Создается новая модель (File/New). Текст модели набирается в появившемся окне. Для запуска модели используется команда Command/CreateSimulation. При этом модель проверяется и появляется новое окно, в котором отображаются результаты проверки. Непосредственно моделирование запускается с помощью пункта Command/START. При этом необходимо указать число N, которое определяет длительность моделирования. При входе в блок TERMINATE k, параметр блока k указывает число, которое необходимо вычесть из того N, которое указывается при старте модели. Когда N станет равной 0, моделирование заканчивается и появляется отчет о результатах моделирования. После этого необходимо выполнить интерпретацию полученных результатов.

Пример 3

Запросы поступают на ЭВМ каждые 7±2 секунд и становятся в очередь, чтобы пройти на обслуживание. Время прохода одного запроса распределено равномерно в диапазоне 5±1 сек. Требуется построить схему и модель работы ЭВМ.

Схема показана на рисунке 12.1.

Имитационная модель:

GENERATE 7,2;генерация запроса

QUEUE OCH;запись запроса в очередь OCH

SEIZE EVM;пересылка запроса в ЭВМ EVM

DEPART OCH;удаление запроса из очереди OCH

ADVANCE 5,1;обработка запроса в ЭВМ EVM

RELEASE EVM;удаление запроса из ЭВМ EVM

TERMINATE 1;удаление запроса из системы

START 10;обработка 10 запросов

 

 

Рис. 12.1. Q схема модели для примера 3,

где З-запрос, О-очередь, Э-ЭВМ

Пример 4

В мастерскую по ремонту оргтехники обращаются 3 вида клиентов: у которых не истек срок гарантийного ремонта, клиентов совершавших покупку данной техники в этой фирме и все остальные клиенты. Приоритеты по ремонту (то есть то, в каком порядке обслуживаются клиенты) определены соответственно. На ремонт одной заявки уходит в среднем 3±2 день. Клиенты первого типа, появляются 20±2 дней, второго - 15±5, 3±1. Разработать схему и смоделировать работу мастерской за один год.

Схема показана на рисунке 12.2.:

 

Рис. 12.2. Q схема модели для примера 4,

где К-клиенты, О-очередь, М-мастерская

Имитационная модель:

;обработка клиентов, у которых не истек срок гарантийного обслуживания

GENERATE 20,2,,,2;генерация клиентов каждые 20+-2 дней, приоритет 2

QUEUE LINE;запись заказа клиентов в очередь

SEIZE REM;принятие заказа в мастерскую

DEPART LINE;удаление заказа клиентов из очереди

ADVANCE 3,2;обработка заказа 3+-2 дня

RELEASE REM;удаление заказа из мастерской

TERMINATE

 

;обработка клиентов, совершавших покупку оргтехники в данной фирме

GENERATE 15,5,,,1

QUEUE LINE

SEIZE REM

DEPART LINE

ADVANCE 3,2

RELEASE REM

TERMINATE

 

;обработка всех остальных клиентов

GENERATE 3,1,,,0

QUEUE LINE

SEIZE REM

DEPART LINE

ADVANCE 3,2

RELEASE REM

TERMINATE

 

;моделирование модели в течении года (365 дней)

GENERATE 365

TERMINATE 1

START 1

 

Контрольные вопросы

1. Назовите средства имитационного моделирования.

2. Для чего нужна Q – схема?

3. Перечислите основные конструкции языка GPSS.

4. Что такое транзакт?

5. Как происходит управление модельным временем в языке GPSS?