Знакомство со средой Visual Basic . Создание простейшего приложения.

Методические указания

к лабораторным работам по дисциплине «Компьютерная техника и программирование »

основы программирования

на языке «Visual Basic»

 

Краматорск 2002

Содержание

 

1. Запуск Visual Basic.

2. Рабочая среда Visual Basic.

3. Выполнение приложения.

4. Требования к выполнению и оформлению лабораторных работ.

Лабораторная работа №1. Знакомство со средой Visual Basic. Создание простейшего приложения.

Лабораторная работа №2. Условные операторы. Вычисления значения функции заданной условно.

Лабораторная работа №3. Циклический алгоритм. Табулирование функции. Поиск экстремумов.

Лабораторная работа №4. Создание и обработка массива.

Лабораторная работа №5. Элементы графики.

Лабораторная работа №6. Создание и обработка файлов. Диалоговые окна.

Лабораторная работа №7. Создание операционного меню.

Лабораторная работа №8. Анимационные рисунки.

 

Запуск Visual Basic

 

Запустить Visual Basic, как и любое Windows-приложение, можно:

· двойным щелчком на пиктограмме (значке программы) на Рабочем столе;

· с помощью Главного меню;

· в окнах программ Мой компьютер, Проводник или Far Manager;

· если есть разработанный уже проект (файл с расширением *.vbp), двойной щелчок на нем запускает Visual Basic и сразу загружает проект.

После запуска Visual Basic появится диалоговое окно, в котором можно выбрать тип создаваемого приложения (Рис 1.). Из этого же окна можно загрузить уже существующий проект.

Рис 1. Диалоговое окно запуска Visual Basic.

 

За некоторыми пиктограммами диалогового окна скрываются мастера приложений (VB Aplication Wisard), сопровождающие разработчика при создании приложений и берущие на себя часть его работы, например, подключение баз данных и создание форм.

Мастер приложений генерирует только скелет программ (Sceleton Programm) – программную оболочку, которую затем необходимо заполнить кодом. Это еще не рабочее приложение, а только базовое приложение (заготовка), к которому затем следует добавить свою специфику.

При создании приложения «с нуля», без использования мастеров приложений, разработчик сам контролирует каждый аспект разработки приложения и сам помещает все элементы управления программы в форму. При этом им необходимо назначить имена, позиционировать их, задать свойства, установить размеры и подключить коды обработки событий. Чтобы создать приложение «с нуля», необходимо запустить Visual Basic и сделать двойной щелчок на значке Standard EXE. Появится рабочая среда Visual Basic.

Сохранение проекта на магнитном диске, а также загрузка в рабочую среду раннее созданного проекта осуществляется стандартно, с помощью меню File (Файл) пунктов Save (Сохранить), Save As (Сохранить как …) и Open (Открыть) соответственно.

 

Рабочая среда Visual Basic

 

 

Рабочая среда (Developer Studio) – это рабочее место разработчика. Главное окно рабочей среды представлено на рис.2.

 

Рис 2. Рабочая среда Visual Basic.

 

Среда Visual Basic выглядит подобно другим приложениям. Многие команды в меню Visual Basic работают также как и в других приложениях. Панель инструментов обеспечивает доступ ко многим командам меню с помощью одной кнопки. Как и другие приложения, Visual Basic поддерживает широкий диапазон панелей инструментов, список которых можно увидеть с помощью команды View Þ Toolbars (Вид Þ Панель инструментов). Каждая отражаемая в данный момент панель инструментов отмечена флажком рядом с ее именем.

Рабочая среда содержит ряд подчиненных окон, которые можно открыть с помощью операционного меню View (Вид) или соответствующих кнопок на панели инструментов.

Окно формы (Form) - главный элемент приложения, основная рабочая область (рис.3). Иногда называется просто формой. Представляет собой контейнер для элементов управления. Точки сетки формы только помогают размещению элементов и при работе приложения не видны. При запуске Visual Basic пустое окно формы появляется в верхнем левом углу рабочей области (рядом с инструментальными средствами). Размер окна небольшой, однако, его можно изменить до любых требуемых размеров. Первой задачей разработчика является размещение в форме соответствующих элементов управления.

 

Рис 3. Окно формы.

 

Проект может содержать несколько форм, т.е. Visual Basic поддерживает режим MDI (Multiple-Document Interface) – интерфейс Windows по работе с несколькими документами.

Для включения в проект новой формы следует воспользоваться командой Project Þ Add Form (Проект Þ Добавить форму).

Панель элементов (Toolbox) содержит перечень необходимых для создания приложения элементов управления (Control): кнопки, переключатели, флажки, поля ввода и др. (рис.4). Это набор прототипов, на основе которых разработчик строит свои объекты, придавая им особые (специфические) значения свойств. Чтобы создать объект в форме с помощью Toolbox, необходимо щелкнуть мышью на соответствующем прототипе в панели элементов (указатель мыши примет форму крестика) и установить в окне формы позицию и размер элемента управления: поместить курсор в один угол конструируемого элемента и перетащить в противоположный. После двойного щелчка на прототипе в центре формы появляется соответствующий элемент стандартного размера. Созданный любым способом объект можно переместить в требуемое место, изменить его размер.

Стандартное окно Toolbox содержит так называемые встроенные (внутренние) элементы управления. Некоторые дополнительные инструментальные средства можно добавить посредством опции меню Project Þ Component.

 

Рис 4. Панель элементов

Набор элементов управления может расширяться за счет так называемых пользовательскихэлементов управления (Custom Controls). Окно свойств (Properties), или окно Параметров содержит перечень и значения свойств выбранного элемента управления (рис.5.). Для отображения окна свойств нажать F4, щелкнуть соответствующую кнопку на панели инструментов или выбрать команду View Þ Properties Window (Вид Þ Окно Параметров). В строке заголовка окна свойств рядом с текстом Properties (Параметры) указывается имя формы, которой принадлежат элементы управления. Поле со списком под строкой заголовка позволяет выбрать требуемый элемент управления. В этом списке присутствует также и имя самой формы, то есть свойства можно задавить и для формы в целом.

Рис.5. Окно свойств.

В списке, расположенном ниже, перечислены свойства выбранного элемента управления. Набор свойств зависит от типа элемента. Список свойств состоит из двух столбцов: в левом перечислены названия свойств, а в правом – их значения. Окно Properties по умолчанию отображает свойства в алфавитном порядке (вкладка Alphabeta (Алфавитный)) с возможным исключением в верхней части окна (например, для свойства Name – Имя элемента управления). При щелчке на ярлыке вкладки Categorized (Категории) над значениями свойств окно Properties изменяется и отображает свойства в виде дерева Explorer (т. е. откроется другая вкладка). Свойства определяют внешний вид и функционирование элементов управления. Редактирование свойств можно выполнить:

- вручную, например ввод Подписи (Caption);

- путем выбора из списка, например, внешний вид (Appearance). Кнопка раскрывающегося списка находится в правом углу окна значения;

- при помощи диалогового окна настройки свойства, например настройка цветового оформления элемента – цвета фона (BackColor), цвета символов или линий (ForeColor), или цвета заполнения рисованных объектов (FillColor);

- автоматически при изменении свойств элементов управления непосредственно в форме, например, при изменении с помощью мыши позиции элемента: координат верхнего левого угла (Top и Left), его высоты (Height) и ширины (Width);

- значения некоторых свойств могут быть изменены при выполнении приложения (т.е. в режиме Run Time).

Примечание. Для измерения размеров и местоположения форм на экране и объектов на форме в Visual Basic используется экранно-независимая единица Твип (Twip) – 1/440 дюйма или 1/20 точки принтера. Это наименьшее экранное измерение, которое можно настроить.

Окно проекта (Project Explorer или просто Project ). В этом окне отражается древовидная структура проекта (рис.6).

В Visual Basic все разрабатываемые приложения называются проектами. Это отражает тот факт, что разработчик создает не просто программу, а проект. В процессе проектирования создаются (рисуются) различные объекты, которые связываются затем кодом. Проект, таким образом, строится по модульному принципу и содержит несколько групп компонентов: форм, модулей и т.п.

Все компоненты проекта сохраняются как отдельные и независимые файлы. Поэтому их в любое время можно загружать и сохранять. Это дает возможность использовать в проекте формы и коды, созданные для других проектов.

Окно проекта описывает два важных аспекта VB – проекта: внешние имена файлов проекта и их внутренние имена, используемые внутри проекта.

Чтобы сохранить существующий компонент проекта (форму, модуль и т.д.) нужно выделить его в списке окна проекта и выбрать команду File Þ Save (Файл Þ Сохранить) или File Þ Save As … (Файл Þ Сохранить как …) (для сохранения под другим именем). Для сохранения всего проекта (включая все компоненты) выбрать команду File Þ Save Project (Файл Þ Сохранить Проект) или File Þ Save Project As … (Файл Þ Сохранить Проект как …) (для сохранения под другим именем).

Рис 6. Окно проекта.

 

Содержимое окна проекта сохраняется в специальном файле с расширением .vbp содержащем список компонентов, которые необходимо загрузить в среду при загрузке проекта, а также все связи между ними.

При загрузки проекта командой File Þ Open Project (Файл Þ Открыть Проект) загружаются все компоненты с учетом связей между ними.

Чтобы добавить в проект новый компонент необходимо воспользоваться командой Project Þ Add (Проект Þ Добавить).

Для удаления компонента из проекта его следует выделить щелчком в окне проекта, затем выбрать команду Project Þ Remove (Проект Þ Удалить).

Для работы с определенной частью загруженного проекта следует сделать двойной щелчок на этом компоненте в окне проекта.

В верхней части окна проекта размещены кнопки View Object (Показать Объект) и View Code (Показать Код). С помощью этих кнопок можно быстро переключаться между окном конструктора формы и окном кода.

В таблице 1 приведен список наиболее часто используемых компонентов, входящих в проект Visual Basic.

 

Табл 1. Составляющие проекта Visual Basic.

Компонент	Расширение файла
Форма	FRM
Модуль класса	CLS
Модуль Basic	BAS
Файл ресурсов	RES
OLE Custom Control	OCX
Файл проекта Visual Basic	VBP
Группа проекта	VBG
Исходный код управления Active X	CTL
Документ Active X	VBD
Файл сообщений Crуstal Report	RPT
База данных MS Access	MDB
Файл сохранения установок	INI
Файл рисунков	BMP
Справочный файл Windows	HLP
Текстовый файл (Rich text format)	RTF
Файл пиктограмм	ICO
Библиотека динамической компоновки	DLL

 

Окно кода (Code) служит для ввода программного кода. Сразу после запуска Visual Basic это окно не отображается. Причина тому – событийно–управляемая ориентация Visual Basic (как и Windows в целом). Это означает, что в Visual Basic нет единого программного кода. Он разделяется на отдельные процедуры, связанные непосредственно с определенными элементами управления и действиями над этими элементами – событиями. Для выполнения кода процедуры необходимо событие – щелчок на элементе, двойной щелчок, перетаскивание т.д. Каждый элемент управления (в т.ч. и сама форма) имеет свой, присущий его типу набор событий. Только при наступлении события начинается выполнение связанного с ним кода процедуры обработки события.

Открыть окно кода для конкретного элемента управления можно двойным щелчком на элементе в окне формы, нажатием клавиши F7 или выбрав команду View Þ Code (Вид Þ Код) в окне проекта.

Окно кода состоит из двух раскрывающихся списков и области редактирования кода (рис.7).

Раскрывающийся список в левой верхней части окна (Objekt - Объект) позволяет выбрать элемент управления, а в верхней правой части (Procedure - Процедура) – событие для выбранного элемента управления. Код (процедуру) для обработки выбранного события выбранного элемента управления можно вводить или корректировать в области редактирования кода.

Имя процедуры обработки события отражает событие, с которым связана эта процедура, т.е. при наступлении которого запускается процедура.

Рис.7. Окно кода

 

Таким образом, полное имя процедуры обработки события предопределено и состоит из имени объекта (элемента управления) и имени события, разделенных символом подчеркивания.

Помимо процедур обработки событий могут создаваться и процедуры общего назначения, не связанные ни с каким событием. Их вызов организует разработчик по своему усмотрению (из других процедур). Имя такой процедуры определяется произвольно. Для ее создания достаточно в окне кода (но не внутри другой процедуры ввести ключевое слово Sub и имя процедуры).

Так как процедура общего назначения не связана ни с одним элементом управления, то поле Object окна кода вместо имени объекта содержит строку General. Окно Procedure определяет имя процедуры.

Код, хранящийся вместе с формой, называется модулем формы. В нем хранятся все процедуры обработки событий для элементов управления формы, а также процедуры общего назначения.

Процедуры общего назначения могут объединяться в модуле общего назначения, являющимся отдельным элементом проекта.

Для открытия окна кода для модуля общего назначения следует сделать двойной щелчок на его имени в окне проекта. Для создания нового модуля следует выполнить команду Project Þ Add Module (Проект Þ Добавить Модуль).

Процессом ввода кода в окне кода управляет редактор кода. В принципе приемы работы в нем такие же, как при редактировании текстов в других приложениях Windows.

Окно управления раскладкой Form Layout (План Формы) предназначено для управления раскладкой форм на экране монитора при запуске приложения на выполнение (рис. 8.).

 

Рис 8. Окно управления раскладкой.

В этом окне можно устанавливать размер и взаимное расположение форм на экране.

Отображает исходную позицию и относительный размер текущей формы, показанной в окне Form. Перемещая форму в окне Form Layout, можно передвинуть позицию, в которой появляется форма при запуске приложения, изменить ее размеры. При этом автоматически изменяются соответствующие свойства формы.

 

Выполнение приложения

 

Для запуска соответствующего приложения на выполнение следует щелкнуть на кнопке Start (Старт) на панели инструментов (значок со стрелкой, направленной вправо) нажать клавишу F5 на клавиатуре или воспользоваться операционным меню Run (Пуск), выбрать в нем пункт Run.

Чтобы закрыть приложение (завершить его выполнение), достаточно закрыть его окно любым способом, предусмотренным в Windows или воспользоваться кнопкой Stop (Прервать) на панели инструментов. Кроме того, в окне приложения обычно предусматриваются командные кнопки для его завершения.

В случае «зависания» (например, при «зацикливании») приложение можно прервать комбинацией клавиш Ctrl + Break. После этого его следует сбросить (завершить) командой Run Þ End (Пуск Þ Конец) или запустить с начала Run Þ Restart (Пуск ÞПовторный старт).

Чтобы приложение Visual Basic могло выполняться не только в среде Visual Basic, его необходимо откомпилировать. Для этого служит команда: File Þ Make ***.exe (Файл Þ Делать ***.ехе).

4. Требование к выполнению и оформлению лабораторных работ

 

1. Каждый студент получает у преподавателя номер своего варианта, который сохраняется в течение всего семестра (при выполнении всех лабораторных работ).

2. Каждый студент создает в папке своей группы личную папку, в которую помещаются все результаты работы. В качестве имени личной папки должна быть использована фамилия студента.

3. Копии личной папки студент хранит на дискете, выполняя соответствующие копирования в начале и конце каждого занятия.

4. Имена всех компонентов проекта должны содержать фамилию студента и иметь следующую структуру:

L<№ лаб>_<ФИО>_<имя компонента>,

где:

<№ лаб> - номер лабораторной работы;

<ФИО> - фамилия студента;

<имя компонента> - имя элемента проекта.

Например:

L4_Иванов_Forma2

L4_Петров_Project

L3_Сидоров_Module2

5. Заголовок каждой формы (свойство Caption) должен содержать номер лабораторной работы и фамилию студента.

 

Работы, выполненные с нарушениями п.4, п.5 не рассматриваются и

не принимаются!!!

 

6. Работа предъявляется на экране компьютера и в виде распечаток кодов Visual Basic. по указанию преподавателя составляются отчеты. Каждая работа должна быть защищена.

7. К каждой работе приведены методические указания по ее выполнению. Студент не обязан строго следовать этим указаниям. Допускается отклонение в оформлении форм элементов управления и т.п. Однако, в целом направление работы должно быть выдержано.

8. Перед каждой лабораторной работой студент должен проработать самостоятельно теоретический материал, относящийся к теме работы и сдать тест.

9. Не допускается создание нового проекта на базе проекта из предыдущей лабораторной работы путем модификации старого проекта.

 

Все проекты должны быть сохранены!!!

В конце семестра все проекты по всему курсу предъявляются преподавателю, принимающему экзамен или ведущему лабораторные работы.

 

Лабораторная работа № 1

Порядок выполнения работы

1. Проверить наличие личной папки. Если ее нет – создать.

2. Войти в среду Visual Basic.

3. Создать новый проект, выбрав в диалоговом окне запуска (рис.1) создание нового проекта Standart Exe. Присвоить созданному проекту имя Lab1. Для этого в окне проекта (Project) выбрать первую строку (строку проекта) и затем открыть окно свойств командой View Þ Properties Window. (Вид Þ Окно Параметров) В появившемся окне свойств Properties (Параметры) для свойств Name указать значение Lab1.

4. Используя меню View включить/отключить основные окна среды Visual Basic: окно форм, окно кода, окно управления раскладкой, окно свойств, панель элементов, окно проекта. Описать назначение каждого окна. Как еще можно открыть и закрыть эти окна?

5. Изменить значение свойства Name формы на Form1. Свойству Caption присвоить значение «Лаб№1. Выполнил <ФИО>. Группа <группа>». Этот текст будет отображаться в строке заголовка формы при запуске приложения.

6. Запустить приложение, т.е. перейти в режим Run-Time. Для этого нажать клавишу F5. Закрыть приложение. Описать, какие еще есть способы запуска приложения.

7. Используя панель элементов управления ToolBox cоздать в форме командную кнопку (элемент управления типа CommandButton) с именем «EXIT» (свойство Name) и написать на ней «Выход» (свойство Caption).

Путем изменения свойств и повременного переключения в режим Run-Time и обратно – в режим конструктора исследовать и описать такие свойства командной кнопки, как размеры, местоположение, цветовое оформление, внешний вид, вид и параметры шрифта и т.п.

8. Аналогично создать кнопку Hello с подписью «Привет».

9. Запустить приложение на выполнение. Реагируют ли кнопки на щелчки? Возвратиться в режим конструктора.

10. Двойным щелчком на кнопке EXIT войти в окно кода формы и ввести следующий код обработки события Click кнопки EXIT (обрамляющие строки будут сгенерированы Visual Basic автоматически):

Private Sub EXIT_Click()

End

End Sub

11. С событием Clik кнопки Hello связать следующий код:

Private Sub Hello_Click()

Print “Привет! Моя первая программа”

End Sub

12. Запустить приложение на выполнение (F5). Как теперь реагируют на щелчки командные кнопки Hello и EXIT? Сделать несколько щелчков на кнопке Hello.

13. Изменить процедуру обработки события Click кнопки Hello, включить в нее дополнительные инструкции для запроса и установки размера шрифта:

Private Sub Hello_Click()

Dim i as integer

i = InputBox(“Введите размер шрифта”)

Font.Size = i

Print “Привет! Моя первая программа”

End Sub

Как теперь работает приложение? Сделайте несколько щелчков на кнопке, задавая каждый раз разные размеры шрифта.

14. Создать в форме элемент управления Check1 типа CheckBox (флажок) с подписью «Подчеркивание».

15. В процедуру обработки события Click кнопки Hello добавить запрос размера шрифта, а также установку/снятие режима подчеркивания в зависимости от состояния флажка Check1:

Private Sub Hello_Click()

Dim i as integer

i = InputBox(“Введите размер шрифта”)

Font.Size = i

Font.Underline = Check1.Value

Print “Привет! Моя первая программа”

End Sub

Запустить приложение на выполнение. Какова теперь реакция приложения на щелчки на кнопке Hello при разных установках флажка Check1.

16. Изменить код процедуры Hello_Click() так, чтобы сообщение выводилось в центре формы. Для этого с помощью методов TextHeight и TextWidth определить фактическую высоту и ширину выводимой строки. Размеры (высота и ширина) рабочей области формы (области, доступной для размещения информации) находятся в свойствах ScaleHeight и ScaleWidth соответственно. Процедура имеет вид:

Private Sub Hello_Click()

Dim Str as string

Dim i as integer

Str = “Привет! Моя первая программа”

i = InputBox(“Введите размер шрифта”)

Font.Size = i

Font.Underline = Check1.Value

CurrentY = (ScaleHeight – TextHeight(Str))/2

CurrentX = (ScaleWidth – TextWidth(Str))/2

Print Str

End Sub

Запустить приложение на выполнение и проверить его работу.

17. Создать в форме элемент управления Text1 типа TextBox (Текстовое поле) и соответствующую ему подпись – элемент управления Label1 типа Label (Надпись) с надписью (свойство Caption) “Введите текст”, как показано на рис.9.

 

Рис.9. Проект формы Form1.

 

18. Изменить код процедуры Hello_Click() так, чтобы введенный в поле Text1 текст объединялся с заранее определенным текстом. Для этого используется операция конкатенации (объединение) - &. Чтобы текст не сливался, следует после слова «программа» добавить пробел.

 

Private Sub Hello_Click()

Dim i As Integer

Dim str As String

Cls

str = "Привет! Моя первая программа " & _

Text1.Text

i = InputBox("Введите размер шрифта")

Font.Size = i

Font.Underline = Check1.Value

CurrentY = (ScaleHeight - TextHeight(str)) / 2

CurrentX = (ScaleWidth - TextWidth(str)) / 2

Print str

End Sub

 

Запустить приложение на выполнение и проверить его работу.

19. Командой Project Þ Add Form (Проект Þ Добавить форму) создать форму Form2, а в ней командную кнопку EXIT с надписью «Закрыть» для закрытия этой формы. С событием Click для этой кнопки связать код:

Private Sub Exit_Click()

Visible = False

End Sub

Присвоение свойству Visible (Видимость) этой формы значения False (Ложь) делает форму невидимой (убирает с экрана).

20. В форме Form1 создать командную кнопку F2 с надписью «Запуск формы» и процедурой обработки события Click:

Private Sub F2_Click()

Form2.Visible = True

End Sub

Выполнение этого кода приводит к появлению на экране формы Form2 (она становится видимой). Удостовериться в этом можно, перейдя в режим Run-Time и попеременно включая /отключая форму.

21. Используя элемент управления Image, Line, Shape, Label оформить внешний вид формы Form2. При этом выбрать различные цвета, толщину линий и т.п.

22. Используя окно управления раскладкой Form Layout (План формы), разместить формы Form1 и Form2 на экране так, чтобы они не перекрывали друг друга.

23. Сохранить результаты в личной папке, соблюдая требования, изложенные в разделе 4. Именно, присвоив следующие имена файлов:

Форма 1: L1_<ФИО>_Form1

Форма 2: L1_<ФИО>_Form2

Проект: L1_<ФИО>_Project

24. По результатам работы составить отчет.

 

 

Лабораторная работа № 2

Пример выполнения работы

Создать приложение для вычисления значения функции:

y=f(x) =

1. Войти в среду Visual Basic. Создать новый проект. Присвоить ему имя Lab2.

2. Используя панель элементов управления, спроектировать форму Form1, примерно как показано на рис.10.

 

Рис 10. Проект формы Form1.

 

В форму включить следующие элементы управления:

а) текстовые поля (TextBox):

- A - для ввода значения параметра а;

- х - для ввода значения аргумента х;

- Y - для вывода значения функции у.

Значения свойств Text для этих полей очистить или присвоить им какие-то начальные значения;

б) Надписи (Label) для каждого текстового поля;

в) командные кнопки;

- Command1 с подписью Расчет;

- Command2 с подписью Выход.

3. Установить для текстового поля Y свойство:

BackColor ( фоновый цвет ) – Button Face;

Visible ( видимость поля) – False;

BordureStyle (стиль рамки) – 0 – None;

Locked (доступность для редактирования) – False.

4. Для командной кнопки Command1 (Расчет) свойству Default присвоить значение True для автоматического вызова события Click для этой кнопки при нажатии клавиши Enter. Аналогично свойству Cancel командной кнопки Command2 (Выход) установить значение True для автоматического вызова события Click для этой кнопки при нажатии клавиши Esc.

5. По своему усмотрению изменить другие свойства элементов управления (цвет, шрифт, подчеркивание, курсив и т.д.), а также добавить дополнительные элементы управления для оформления форм (линии, фигуры, рисунки и т.д.).

6. Создать модуль Module1. Для этого выбрать команду Project Þ Add Module (Проект Þ Добавить модуль). В появившемся окне кода набрать следующий код:

 

Function f(X As Single) As Single

If X <= 0 Then

f = Sin(X ^ 2 + Form1.A * X)

ElseIf X <= Form1.A Then

f = 1 - (1 + Sqr(X2 + Form1.A * X)) / (Exp(Sin(X)) * (1 + X))

Else

f = Cos(X ^ 2 - Form1.A ^ 2) / Sqr(1 - Sin(X - Form1.A)) - _

(1 - Sin(Form1.A - X)) / Exp(Sin(X))

End If

End Function

 

Этот код предназначен для вычисления значения функции. В этом коде используется формальный параметр А из Form1. имя формы должно предшествовать имени элемента управления и отделяться от него точкой. Имя свойства (Text) можно опустить.

7. С событием Click командной кнопки Command1 (Расчет) связать следующий код:

Private Sub Command1_Click()

Y = f(X)

Y.Visible = True

End Sub

Этот код предназначен для вычисления значения функции и присвоения его свойству Text текстового поля Y (имя свойства Text можно опустить). При этом поле становится видимым (появляется на экране), т.к. его свойству Visible (Видимость) присвоено значение True (Истина).

8. С событием Click кнопки Command2 (Выход) связать код.

Private Sub Command2_Click()

End

End Sub

9. С событием GotFocus (Получения фокуса) текстового поля X связать код:

 

Private Sub X_GotFocus()

Y.Visible = False

End Sub

 

Это событие возникает при переходе к данному элементу (например, щелчком или при помощи Tab или Shift + Tab) и означает, готовность к приему данных в поле Х. Процедура обработки события делает невидимым поле Y, убирая с экрана результат предыдущего расчета, относящийся к старому содержанию поля Х.

10. Аналогично создать код для обработки события GotFocus для текстового поля A:

 

Private Sub A_GotFocus()

Y.Visible = False

End Sub

 

11. С событием LostFocus (Потеря Фокуса) текстового поля Х связать код:

 

Private Sub X_LostFocus()

If Not IsNumeric(X) Then

X.SetFocus

MsgBox "Неверное значение: не цифра"

End If

End Sub

 

Это событие наступает после потери фокуса элементом управления, т.е. после завершения ввода или корректировки данных и передачи фокуса другому элементу. Приведенная выше процедура обработки данного события с помощью встроенной функции IsNumeric() проверяет, можно ли введенное значение преобразовать к числовому типу. При отрицательном результате с помощью встроенной функции MsgBox выводится сообщение об ошибке и фокус возвращается к полю Х для исправления ошибок.

12. Аналогично с событием LostFocus текстового поля A связать код:

 

Private Sub A_LostFocus()

If Not IsNumeric(A) Then

A.SetFocus

MsgBox "Неверное значение: не цифра"

End If

End Sub

13. Сохранить проект в личной папке соблюдая требования, изложенные в разделе 4:

Форма: L2_<ФИО>_Form1

Модуль: L2_<ФИО>_Module1

Проект: L2_<ФИО>_Project

14. Запустить приложение на выполнение и выполнить расчет значений функции для различных значений аргумента.

Лабораторная работа № 3.

Пример выполнения работы.

 

1. Войти в среду Visual Basic, создать новый проект, присвоить ему имя Lab3.

2. Спроектировать форму примерно, как на рис. 11.

Рис. 11. Проект формы Form1.

 

Форма содержит следующие элементы управления:

а) текстовые поля (TextBox):

A - значение параметра а;

Xnac - начальное значение аргумента;

Xkon - конечное значение аргумента;

hx - шаг табулирования (величина приращения аргумента).

б) надписи (Lаbel) для каждого текстового поля и заглавной надписи;

в) командные кнопки:

Command1 - выполнение расчетов;

Command2 - завершение работы, выход.

3. С помощью команды Project Þ Add Form (Проект Þ Добавить Форму) создать форму Form2 для размещения результатов работы приложения, включив в нее один объект – надпись, содержащую заголовок таблицы, примерно как показано на рис.12.

Рис.12. Проект формы Form 2.

 

4. Добавить в проект модуль Module1, разработанный в рамках проекта Lab2 для вычисления значения функции в заданной точке. Для этого выполнить команду Project Þ Add File (Проект Þ Добавить файл). В появившемся окне диалога найти свою папку и выбрать модуль L2_<ФИО>_Modul1.

5. В модуле формы Form1 создать следующий код обработки событий:

 

Private Sub Command1_Click()

Dim YMin As Single, YMax As Single

Dim X As Single, y As Single

Dim i As Integer

X = Xnac

y = f(X)

YMax = y: YMin = y

Form2.Visible = True

Form2.Cls

Form2.CurrentY = 800

Form2.CurrentX = 1000

Form2.Print " x", " f(x)"

Form2.CurrentX = 1000

Form2.Print

Do While X < Xkon

y = f(X)

Form2.CurrentX = 1000

Form2.Print Format(X, "####0.00"), Format(y, "###0.000")

If y > YMax Then YMax = y

If y < YMin Then YMin = y

X = X + hX

Loop

Form2.Print

Form2.Print "Максимальное значение", Format(YMax, "###0.000")

Form2.Print "Минимальное значение", Format(YMin, "###0.000")

End Sub

 

6. Создать коды обработки событий для командной кнопки Command2 и текстовых полей Xnac, Xkon, hx и A формы аналогично тому, как это сделано в лабораторной работе №2 (пп.8-12).

7. Сохранить проект в личной папке, соблюдая требования, изложенные в разделе 4, т.е., присвоив следующие имена файлов:

Форма 1: L3_<ФИО>_Form1

Форма 2: L3_<ФИО>_Form1

Проект: L3_<ФИО>_Project

8. Запустить приложение на выполнение. Выполнить расчеты несколько раз, меняя диапазон и шаг табулирования.

Лабораторная работа №4.

Порядок выполнения работы

1. Войти в среду Visual Basic, создать новый проект, присвоить ему имя Lab4.

2. Создать проект формы Form1, как показано на рис.13. Элементы управления те же, что и в проекте Lab3.

 

Рис.13 Проект формы Form1.

 

3. Создать форму Form2, включить в нее помимо заголовка элемент VscrollBar (вертикальная полоса прокрутки), как показано на рис.14.

 

Рис.14. Проект формы Form2.

Установить для полосы прокрутки свойства:

SmallChange = 1(величина изменения свойства Value при щелчке на одной из двух кнопок со стрелками).

LargeChange = 10 (величина изменения свойства Value при щелчке в области между бегунком и кнопкой со стрелками).

Минимальное значение диапазона прокрутки (Min) должно быть установлено в нуль (эта установка принимается по умолчанию), а максимальное (Max) можно не задавать, т.к. его значение будет установлено в процедуре обработки.

4. Добавить в проект модуль Module1, разработанный в проекте Lab2 (см. лабораторную работу №3, пункт 4)..

5. Создать новый модуль Module2. В окне кода этого модуля ввести следующий код:

 

Public XMin As Single, XMax As Single

Public YMin As Single, YMax As Single

Public n As Integer

Public MX() As Single, MY() As Single

' Определили массивы MX и MY без объявления размерности

Public Sub TabFunc(xn As Single, xk As Single, h As Single)

'Процедура табулирования функции

 

Dim x As Single, y As Single

Dim i As Integer

 

n = (xk - xn) / h

'Определяем размерность массива, т.е. количество точек в

'таблице значений (следует иметь в виду,

'что отсчет начинается с нуля)

ReDim MX(n), MY(n)

'Устанавливаем фактический размер массивов

Form2.VScroll1.Max = n

'Установили максимальное значение диапазона прокрутки

x = xn

y = f(x)

YMax = y: YMin = y

'Присвоили начальные значения для цикла и организовываем цикл

'для вычисления таблиц