Часть III. Программирование на Паскале – второй уровень

Если вам кажется, что вы уже все можете, то вы правы и неправы. Правы потому, что вы можете написать сколь угодно большую программу, разбив ее на разумное число процедур. Неправы потому, что ваша способность манипулировать данными в памяти компьютера еще очень ограничена. А без нее вам не поддадутся «умные» задачи. Например, не познакомившись с так называемыми массивами, вы не сможете запрограммировать игру в крестики-нолики или решить задачу о выходе из лабиринта; не освоив работу со строками, символами и файлами, вы не сможете решить задачу о мало-мальски серьезной секретной шифровке и расшифровке сообщений.

Эта часть посвящена тому, чтобы

· Расширить ваши знания о возможностях Паскаля

· Сделать ваши знания о Паскале строгими, иначе вы не сможете исправлять в программах грамматические ошибки, а значит программы у вас работать не будут.

 

Начнем с наведения порядка в наших знаниях о Паскале.

 

 

Глава 11. Алфавит и ключевые слова Паскаля

Алфавит

У каждого языка - свой алфавит. В русском языке нельзя употреблять латинские буквы, в греческом - китайские иероглифы и т.д., иначе вас мало кто поймет.

В Паскале тоже есть свой алфавит - четкий набор символов, которые вы имеете право употреблять в программе. Ни одного другого символа употреблять нельзя.

 

Вот алфавит Паскаля:

 

1) Латинские заглавные (прописные) буквы: A, B, C, D,......., Z.

2) Латинские малые (строчные) буквы: a, b, c, d,......., z.

3) Десять цифр: 0,1,2,3,4,5,6,7,8,9.

4) Символы подчеркивания “_” и пробела “ “.

5) Специальные символы: + - * / = < > () [ ] { }.,:; ’ ^ @ $ #

6) В определенных местах программы можно употреблять и все остальные символы, в том числе и русские буквы. Поясню, о каких символах и о каких местах идет речь. Вы знаете (3.5), что для кодирования одного символа в компьютере используется один байт. Ввиду того, что байт состоит из 8 битов, им можно закодировать 256 символов. Все они приведены в так называемой таблице ASCII (в 12.11вам будет предложено распечатать эту таблицу). Большинство из них и имеется в виду. Употреблять их можно только в двух местах:

· В символьных и строковых константах, например, Slovo:=’Чаща’

· Внутри комментариев, например, { Вот символы ASCII: % F! \ Л }

Ключевые слова

Существует несколько десятков слов, некоторым из которых не рекомендуется, а большинству просто запрещено быть именами. Происходит это потому, что Паскаль использует их для более важных дел. Эти запрещенные слова, а заодно уж и нерекомендованные (хоть это и нестрого) мы будем называть ключевыми (их также называют зарезервированными или служебными). Вот ключевые слова языков Borland Pascal 7.0 для DOS и TurboPascal 7.0 (списки ключевых слов других версий Паскаля мало чем отличаются от приведенного):

absolute

AND

array

asm

assembler

begin

case

const

constructor

destructor

div

do

downto

else

end

export

exports

external

far

file

for

forward

function

goto

if

implementation

in

index

inherited

inline

interface

interrupt

label

library

mod

near

nil

not

object

of

or

packed

private

procedure

program

public

record

repeat

resident

set

shl

shr

string

then

to

type

unit

until

uses

var

virtual

while

with

xor

 

Таким образом, если вы ненароком придумаете своей переменной имя asm, Паскаль укажет вам на ошибку.

Использование пробела

· Пробелызапрещены внутри имен и ключевых слов.

· Пробелы обязательны между именами и ключевыми словами (если они находятся в одной строке).

· В остальных случаях пробелы несущественны и могут ставиться произвольно.

· Там, где допускается один пробел, допускается и сколько угодно.

· Вместо нажатия на клавишу пробела можно нажимать на клавишу ввода.

 

Глава 12. Работа с разными типами данных Паскаля

Список типов

Каждая переменная величина в Паскале должна принадлежать какому-нибудь типу: Integer, Char, String и т.п. Вот список практически всех типов, многие из которых нам еще предстоит пройти. Здесь не учтены только так называемые процедурные типы, которые в этой книге освещаться не будут.

 

Простые типы

Числовые типы

Целочисленные типы

Byte

ShortInt

Word

Integer

LongInt

Вещественные типы

Real

Single (при наличии или эмуляции матем. сопроцессора)

Double (при наличии или эмуляции матем. сопроцессора)

Extended (при наличии или эмуляции матем. сопроцессора)

Comp (при наличии или эмуляции матем. сопроцессора)

Символьный тип

Char

Логический тип

Boolean

Перечислимый тип

Ограниченный тип (диапазон)

 

Сложные (структурированные) типы(строятся из простых):

Массивы array

Записи record

Множества set

Строки String

Файлы

Текстовые файлы

Text

Типизированные файлы

File of …

Бестиповые файлы

File

Объекты Object

Ссылки:

Ссылки

Адресный тип

Pointer

 

 

Комментарии к списку типов

Переменная простого типа в каждый момент времени имеет своим значением что-то одно: одно число или один символ и т.п.

Переменная сложного типа состоит из многих элементов, каждый из которых принадлежит простому или сложному типу. Элемент сложного типа в свою очередь раскладывается на другие элементы и так далее. Разложив все до конца, мы получим, что переменная сложного типа состоит из элементов простых типов.

Аналогия: Простой тип. Вы хотите купить продукты. Вы идете по улице и видите дверь с надписью «Лавка». Вы открываете дверь и видите, что там продаются, например, баранки.

Структурированный тип. Вы хотите купить продукты. Вы видите дверь с надписью «Супермаркет». Вы открываете дверь и видите, что там продается множество разных продуктов.

Ссылки. Вы хотите купить продукты. Вы видите дверь с надписью «Адресное бюро». Вы открываете дверь, но внутри никаких продуктов нет. Вместо них вам дают адрес лавки или супермаркета.

Числовые типы

Целочисленные типы позволяют переменной принимать значения целых чисел согласно следующей таблице:

Тип	Диапазон значений	Сколько байтов занимает одно значение
Byte	0..255
ShortInt	-128..127
Word	0..65535
Integer	-32768..32767
LongInt	-2147483648..2147483647

Зачем нужны Byte и ShortInt, если есть Integer? Они занимают меньше места в памяти. Если, например, ваша переменная по смыслу задачи обозначает минуты (то есть целое число в диапазоне от 0 до 60), то полный смысл придать ей тип Byte.

 

Вещественные типы позволяют переменной принимать значения вещественных чисел согласно следующей таблице:

Тип	Примерный диапазон значений	Точность (значащих цифр)	Сколько байтов занимает одно значение
Real	2.9´10^-39 - 1.7´10^38	11-12
Single	1.5´10^-45 - 3.4´10^38	7-8
Double	5´10^-324 - 1.7´10^308	15-16
Extended	3.4´10^-4932- 1.1´10^4932	19-20
Comp [9]	примерно от -10^19 до 10^19

Типы Single, Double, Extended и Comp могут потребовать для своей работы некоторой настройки Паскаля.

Следует помнить, что дробные числа (например, 1/3) компьютер хранит примерно в таком виде: 0,3333333333333. Вы знаете, что такое представление дробных чисел приблизительно. Чтобы точно представить 1/3, компьютеру понадобилось бы бесконечное количество троек, но память компьютера ограничена. Ячейка под переменную типа Real позволяет хранить всего 11-12 таких троек. Эту приблизительностьнужно иметь в виду, когда вы многократно выполняете арифметические действия над переменными вещественных типов. При определенном сочетании чисел и действий вы можете немедленно получить совершенно неправильный результат. Попробуйте, например, выполнить такую программу:

VAR a,b,y: Real;

BEGIN

a:=55555555555.1; b:=55555555555.0;

y:=a-b;

WriteLn (y:30:3)

END.

Вы обнаружите, что вместо результата 0.100 компьютер выдает результат 0.125.

Массивы

Для того, чтобы понять массивы, нужно обладать некоторой культурой математического мышления. Если этот материал покажется вам трудным, не поддавайтесь искушению пропустить его. Настоящего программирования без массивов не бывает, да и большая часть дальнейшего материала без массивов не будет понятна.

Переменные с индексами

В математике широко применяются так называемые индексированные переменные. На бумаге они записываются так:

x₁ x₂ b₈ y_i y_i-6 z_ij z_i+1j

а читаются так: икс первое, икс второе, бэ восьмое, игрек итое, игрек и минус шестое, зет итое житое, зет и плюс первое житое. Поскольку в алфавите Паскаля нет подстрочных букв и цифр, то те же индексированные переменные на Паскале приходится обозначать так:

X[1] X[2] B[8] Y[i] Y[i-6] Z[i,j] Z[i+1,j]

Зачем нужны индексированные переменные? Их удобно применять хотя бы при операциях над числовыми рядами. Числовой ряд – это просто несколько чисел, выстроенных по порядку одно за другим. Чисел в ряду может быть много и даже бесконечно много.

Возьмем, например, бесконечный ряд чисел Фибоначчи: 1 1 2 3 5 8 13 21 34..... Попробуйте догадаться, по какому закону образуются эти числа. Если вы сами не догадались, то я подскажу: каждое из чисел, начиная с третьего, является суммой двух предыдущих. А теперь попробуем записать это утверждение с помощью языка математики. Для этого обозначим каждое из чисел Фибоначчи индексированной переменной таким образом:

Первое число Фибоначчи обозначим так: f[1],

Второе число Фибоначчи обозначим так: f[2] и т.д.

 

Тогда можно записать, что f[1]=1 f[2]=1 f[3]=2 f[4]=3 f[5]=5 f[6]=8......

Очевидно, что f[3]=f[1]+f[2],

f[4]=f[2]+f[3],

f[5]=f[3]+f[4] и т.д.

Как математически одной формулой записать тот факт, что каждое из чисел является суммой двух предыдущих? Математики в индексном виде это записывают так:

f[i]=f[i-2]+f[i-1].

Для иллюстрации подставим вместо i любое число, например, 6. Тогда получится:

f[6]=f[6-2]+f[6-1] или

f[6]=f[4]+f[5].

 

Задание 102: Запишите в индексном виде, как получается из предыдущего числа ряда последующее:

1) 14 18 22 26.....

2) 6 12 24 48....

3) 3 5 9 17 33 65....

Вот еще примеры, когда математики предпочитают использовать индексы. Пусть мы на протяжении года каждый день раз в сутки измеряли температуру за окном Тогда вполне естественно обозначить через t[1] температуру первого дня года, t[2] - второго,....., t[365] - последнего. Пусть 35 спортсменов прыгали в высоту. Тогда через h[1] можно обозначить высоту, взятую первым прыгуном, h[2] - вторым и т.д.

Одномерные массивы

Одна из типичных задач программирования формулируется примерно так. Имеется большое количество данных, например, тех же температур или высот. С этими данными компьютер должен что-нибудь сделать, например, вычислить среднегодовую температуру, количество морозных дней, максимальную взятую высоту и т.п. Раньше мы вычисляли подобные вещи, и данные вводили в компьютер с клавиатуры одно за другим в одну и ту же ячейку памяти (см. 7.7). Однако, программистская практика показывает, что удобно, а часто и необходимо иметь данные в оперативной памяти сразу все, а не по очереди. Тогда для задачи про температуру нам понадобится 365 ячеек. Эти 365 ячеек мы и назовем массивом. Итак, массивом можно назвать ряд ячеек памяти, отведенных для хранения значений индексированной переменной. Вопрос о том, как большое количество значений оказывается в памяти, отложим на будущее (15.1).

Рассмотрим на простом примере, как Паскаль управляется с массивами. Предположим, в зоопарке живут три удава. Известна длина каждого удава в сантиметрах (500, 400 и 600). Какая длина получится у трех удавов, вытянутых в линию?

Обозначим длину первого удава - dlina[1], второго - dlina[2], третьего - dlina[3]. Прикажем Паскалю отвести под эту индексированную переменную массив:

VAR dlina: array [1..3] of Integer

Здесь array означает массив или ряд, 1 - первое значение индекса, 3 - последнее. Две точки обозначают диапазон от 1 до 3 (см. 5.7) В целом эту строку можно перевести так: Отвести в памяти под переменную dlina ряд ячеек типа Integer, пронумерованных от 1 до 3.

Вот программа полностью:

VAR dlina: array [1..3] of Integer;

summa:Integer;

BEGIN

dlina[1]:=500;

dlina[2]:=400;

dlina[3]:=600;

{В этот момент в трех ячейках памяти уже находятся числа

и с ними можно выполнять арифметические действия}

summa:= dlina[1]+dlina[2]+dlina[3];

WriteLn(summa)

END.

Если смысл написанного выше вам неясен, запустите отладочный пошаговый режим выполнения программы, заставив Паскаль показывать вам текущие значения dlina[1], dlina[2], dlina[3], summa.

Теперь запишем ту же программу в предположении, что длины удавов заранее неизвестны и мы их вводим при помощи ReadLn:

VAR dlina: array [1..3] of Integer;

summa:Integer;

BEGIN

ReadLn (dlina[1],dlina[2],dlina[3]);

summa:= dlina[1]+dlina[2]+dlina[3];

WriteLn(summa)

END.

Теперь решим ту же задачу в предположении, что удавов не три, а тысяча:

VAR dlina: array [1..1000] of Integer;

summa, i:Integer;

BEGIN

{Вводим длины тысячи удавов, хоть это и утомительно:}

for i:=1 to 1000 do ReadLn (dlina[i]);

{Здесь на первом выполнении цикла i=1 и поэтому компьютер выполняет ReadLn(dlina[1]),

на втором – i=2 и поэтому компьютер выполняет ReadLn(dlina[2]) и т.д.}

 

{Определяем суммарную длину тысячи удавов:}

summa:= 0;

for i:=1 to 1000 do summa:=summa+dlina[i]);

WriteLn(summa)

END.

Решим еще одну задачу. Дан ряд из 10 произвольных чисел: a[1], a[2],..., a[10]. Подсчитать и напечатать суммы троек стоящих рядом чисел: a[1]+a[2]+a[3], a[2]+a[3]+a[4], a[3]+a[4]+a[5],......, a[8]+a[9]+a[10].

VAR a: array [1..10] of Integer;

i:Integer;

BEGIN

for i:=1 to 10 do ReadLn (a[i]);

for i:=1 to 8 do WriteLn (a[i]+ a[i+1]+ a[i+2])

END.

 

Задание 103:. Напишите программу вычисления среднегодовой температуры (Для проверки в компьютере годом можно считать неделю).

Задание 104:. Подсчитайте количество морозных дней (когда температура ниже -20 град.).

Задание 105:. Каким по порядку идет самый морозный день?

Задание 106:. Вычислить и распечатать первые тридцать чисел Фибоначчи.

12.3.3. Двумерные массивы

Поясним суть двумерных массивов на простом примере. Пусть на целом ряде метеостанций, расположенных в разных точках земного шара, в течение многих дней измеряли температуру воздуха. Показания термометров свели в таблицу. Ограничимся для экономии места тремя станциями и четырьмя днями.

	1-й день	2-й день	3-й день	4-й день
Метеостанция 1	-8	-14	-19	-18
Метеостанция 2
Метеостанция 3

Требуется:

1) Распечатать показания термометров всех метеостанций за 2-й день

2) Определить среднюю температуру на третьей метеостанции

3) Распечатать всю таблицу

4) Распечатать, в какие дни и на каких метеостанциях температура была в диапазоне 24-26 градусов тепла

Для этого обозначим показания термометров индексированной переменной с двумя индексами по следующей схеме:

t[1,1] t[1,2] t[1,3] t[1,4]

t[2,1] t[2,2] t[2,3] t[2,4]

t[3,1] t[3,2] t[3,3] t[3,4]

Обратите внимание, что первый индекс в скобках обозначает номер строки (метеостанции), второй - номер столбца (дня) прямоугольной таблицы.

Программа:

{В памяти отводим массив из 3*4=12 ячеек под значения типа Integer индексированной переменной t. Будем называть его двумерным массивом: }

 

VAR t:array [1..3, 1..4] of Integer;

s,i,j:Integer;

BEGIN {Зададим значения элементов массива примитивным присваиванием:}

t[1,1]:=-8; t[1,2]:=-14; t[1,3]:=-19; t[1,4]:=-18;

t[2,1]:=25; t[2,2]:= 28; t[2,3]:= 26; t[2,4]:= 20;

t[3,1]:=11; t[3,2]:= 18; t[3,3]:= 20; t[3,4]:= 25;

{А теперь распечатаем второй столбец массива:}

for i:=1 to 3 do WriteLn(t[i,2]);

{Определим среднее значение элементов третьей строки:}

i:=3;

s:=0;

for j:=1 to 4 do s:=s+t[i,j];

WriteLn(s/4:10:3);

{Распечатаем всю таблицу:}

for i:=1 to 3 do for j:=1 to 4 do WriteLn (t[i,j]);

{Распечатаем станции и дни с температурой 24-26 градусов:}

for i:=1 to 3 do for j:=1 to 4 do

if (t[i,j]>=24) AND (t[i,j]<=26) then WriteLn ('Станция ',i,' день ',j)

END.

Задание 107: Вычислить разницу между максимальной и минимальной температурой во всей таблице.

Какие бывают массивы

Массивы могут быть одномерные, двумерные, трехмерные, четырехмерные и т.д.:

array [1..10] of Integer -одномерный массив 10 ячеек

array [1..10, 1..5] of Integer -двумерный массив 50 ячеек

array [1..10, 1..5, 1..2] of Integer -трехмерный массив 100 ячеек

array [1..10, 1..5, 1..2, 1..3] of Integer -четырехмерный массив 300 ячеек

 

Массивы бывают не только числовые, но и символьные, строковые и прочие. Подходит любой известный нам тип. Например:

array [1..50] of Char

Это означает, что в каждой из 50 ячеек должно находиться не число, а произвольный символ. Еще один пример:

array [1..50] of String

Здесь в каждой из 50 ячеек должна находиться строка. Примеры программ с такими массивами мы увидим в 12.13.

Границы индексов в квадратных скобках тоже могут быть разными, например:

array [20..60] of Real

Здесь под вещественные числа отводится 41 ячейка.

array [0..9, -10..30] of Real

Здесь под вещественные числа отводится 10*41=410 ячеек.

Вообще индексы могут быть не только числовыми, но и любыми порядковыми. Например,

array [‘А’..’Я’] of Real

Зачем это нужно, будет ясно в 12.8.

Полная синтаксическая информация о массивах будет приведена в 14.8.

 

Какая польза от массивов при программировании игр? Вряд ли хоть одну «умную» игру можно запрограммировать без применения массивов. Возьмем хотя бы «крестики-нолики» на поле 3 на 3. Вам придется рисовать на экране большие клетки, а в них – нолики (кружочки) после ваших ходов и крестики (пересекающиеся линии) после ходов компьютера. Но этого недостаточно. Чтобы компьютер мог поставить крестик в свободном поле, он должен хотя бы знать, а в каких клетках крестики и нолики уже стоят. Анализировать для этого информацию о пикселах экрана очень неудобно. Гораздо разумнее заранее организовать VAR a: array[1..3,1..3] of Byte и записывать туда в нужные места нолики после ходов человека и единички после ходов компьютера. Сразу же после записи в массив 0 или 1 программа должна рисовать в соответствующем месте экрана кружок или крестик. Мыслить компьютер мог бы при помощи примерно таких операторов – if (a[1,1]=0) AND (a[1,2]=0) then a[1,3]:=1. Это очевидный защитный ход компьютера.

 

Определения констант

Приведем программу вычисления среднегодовой температуры для задания 1 из 12.3.

VAR s,i:Integer; t: array [1..365] of Integer;

BEGIN

for i:=1 to 365 do ReadLn(t[i]);

s:=0;

for i:=1 to 365 do s:=s+t[i];

WriteLn(s/365)

END.

Пусть нам потребовалось переделать эту программу на вычисление средней недельной температуры. Для этого достаточно везде в тексте программы число (константу) 365 заменить на число (константу) 7. В больших программах одна и та же константа может встречаться десятки раз и подобный процесс может потребовать значительного расхода времени. В 10.4 мы уже сталкивались с такой ситуацией. Там мы нашли выход в том, что вместо константы записывали переменную величину. Но в нашем случае этого не получится, так как Паскаль запрещает задавать границу в описании массива переменной величиной. В таких случаях поступают следующим образом. Константе придумывают имя (как переменной), например k, и в специальном разделе constей задается значение. Вот наша программа с использованием константы k:

CONST k =365; {Обратите внимание, что в определении вместо := стоит = }

VAR s,i:Integer;

t: array [1..k] of Integer;

BEGIN

for i:=1 to k do ReadLn(t[i]);

s:=0;

for i:=1 to k do s:=s+t[i];

WriteLn(s/k)

END.

В приведенном виде программа стала универсальной. Теперь для ее переделки под средненедельную температуру достаточно в одном месте поменять определение k=365 на k=7.

Значению константы запрещено меняться в процессе выполнения программы, то есть запрещены операторы вида k:=30 и ReadLn(k). Паскаль присматривает за этим.

Тип константы указывать нельзя[10]. Паскаль сам догадается о типе по записи:

CONST n =800; {тип целочисленный}

e =2.7; {тип Real}

bukva =’ж’; {тип Char}

Slash =’/’; {тип Char}

slovo =’хорошо’; {тип String}

OK =true; {тип Boolean}

Имя константы образуется из букв и цифр так же, как и имя переменной. Важное отличие константы от переменной в том, что значение переменной задается на этапе выполнения программы, а значение константы - раньше, на этапе компиляции. Рекомендую вам там, где можно, вместо переменных применять константы. Программа получается строже.

Типизированные константы

В блоке CONST можно описывать не только константы, но и переменные величины. Эти переменные величины из-за того, что они описаны в таком странном месте, приобретают неудачное название типизированные константы, но переменными быть не перестают, а самое для нас главное - здесь им можно удобно придавать начальные значения. Вот пример:

CONST n:Integer =800;

e:Real =2.7;

Вот как запишется программа для вычисления средней недельной температуры из 12.4, если массив t описать как типизированную константу:

CONST k =7; { k - обычная, нетипизированная константа}

t: array [1..k] of Integer = (-14, -12, -8, -2, 0, 1, -3);

{ t - типизированная константа}

VAR s,i:Integer;

BEGIN

s:=0;

for i:=1 to k do s:=s+t[i];

WriteLn(s/k)

END.

Здесь в круглых скобках задается список начальных значений переменной t, а именно: t[1] равно -14, t[2] равно -12 и т.д. В разделе операторов эти значения можно менять.

Двумерным массивам начальные значения придаются аналогично. Так в программе из 12.3 вместо двенадцати присвоений можно было записать так:

Const k =3; n=4;

t: array [1..k,1..n] of Integer = ((-8,-14,-19,-18),

(25, 28, 26, 20),

(11, 18, 20, 25));

.......

Обратите внимание на расстановку скобок.

Придумываем типы данных

Паскаль предоставляет возможность не только пользоваться стандартными типами данных, но также именовать их по-другому и даже создавать свои типы.

Запись TYPE bukva = Char

означает: ТИП bukva "равен" (эквивалентен) типу Char,

то есть мы просто придумали типу Char еще одно название "bukva". Теперь все равно, как записать:

VAR a,b:Char

или VAR a,b:bukva.

 

Еще примеры: type Vector = array [1..10] of Integer;

matritsa = array [1..8] of Vector;

var a,b:Vector;

c:matritsa;

d: array [1.. 8] of Vector;

Здесь мы создали два новых типа с именами Vector и matritsa. Очевидно, переменные c и d описаны одинаково. Обратите внимание, что вместо type matritsa = array [1.. 8] of Vector

можно записать type matritsa = array [1.. 8] of array [1..10] of Integer

или type matritsa = array [1..8,1..10] of Integer.

 

Зачем нужны новые типы? Вот две из нескольких причин. Одна – наглядность и удобство. Другая - чисто грамматическая - Паскаль разрешает в определенных конструкциях записывать лишь имена типов, а не их определения. Например, когда мы изучим процедуры с параметрами, мы узнаем, что

писать procedure p(a: array[1..10] of Integer) неправильно,

а писать procedure p(a: Vector) правильно.

 

Логический тип Boolean

В операторах if, while, repeat мы привыкли писать выражения вида a>b, i<=0, c=’крот’, 3>2, (a>b)AND(a>c) и т.п. Про каждое из этих выражений можно сказать, истинно оно в данный момент или ложно. Например, выражение 3>2 истинно всегда, а выражение i<=0 ложно в тот момент, когда i равно, скажем, 2. Такие выражения называются логическими выражениями.

Говорят, что логическое выражение 3>2 имеет значение “истина” (по-английски true - “тру”), а логическое выражение i<=0 имеет значение “ложь” (по-английски false - “фолс”).

Внутренняя идеология построения языка Паскаль требует определить новый тип переменных - логический тип Boolean. Запись VAR a:Booleanозначает, что переменная aможет принимать всего два значения - true и false. Так, мы можем записать a:=false.

Слова true и false являются логическими константами и их можно употреблять в логических выражениях или вместо них. Например, if a=true then... Конструкцию if (a>b)=false then... можно перевести “если неправда, что a больше b, то...”.

Значения true и false удобно применять для организации бесконечных циклов:

while true do.......

repeat........... until false

Решим конкретный пример на этот тип.

Задача: В группе - 6 студентов. Сколько из них сдали зачет по физике?

Сначала напишем программу без использования типа Boolean. В ней единицей я обозначил зачет, нулем - незачет. Массив Zachet из 6 элементов хранит информацию о зачете.

CONST Zachet: array [1..6] of Integer = (1,1,0,1,1,1);
VAR c,i:Integer;
BEGIN
c:=0; {c - счетчик зачетов}
for i:=1 to 6 do if zachet[i] = 1 then c:=c+1;
WriteLn(c)
END.

Теперь напишем программу с использованием типа Boolean. В ней через true я обозначил зачет, через false - незачет.

CONST Zachet: array [1..6] of Boolean = (true,true, false, true, true, true);
VAR c,i:Integer;
BEGIN
c:=0;
for i:=1 to 6 do if zachet[i] = true then c:=c+1;
WriteLn(c)
END.

Отличие второй программы от первой в том, что выражение zachet[i] = true (зачет равен истина) выглядит естественнее и понятнее, чем zachet[i] = 1 (зачет равен единице, то есть колу?). В общем, чуть-чуть нагляднее.

Кстати, вполне правильно было бы написать и if zachet[i] then.... Ведь условием после слова if может стоять любое логическое выражение, имеющее значением true или false.

Перечислимые типы

В 5.7 я говорил о порядковых типах- это те типы, все значения которых можно выстроить по порядку и перечислить от начала до конца. Мы пока знаем, что в Паскале порядковыми типами являются целочисленные типы, символьный тип и логический тип. Кроме того, программист может придумывать собственные порядковые типы. Рассмотрим, например, такую конструкцию:

VAR Month: (january, february, march, april, may, june, july, august, september, october, november, december)

Она означает, что переменная Month может принимать только одно из перечисленных в скобках значений. Например, можно записать Month:= may. Переменная Month является переменной перечислимого типа, который является одним из видов порядковых типов.

Эти значения ни в коем случае не являются строками. Так, нельзя записать Month:= ‘may’. Кроме того, их нельзя вывести на печать, вообще они не могут быть введены в компьютер или выведены из него, например, при помощи операторов Read и Write. Однако, их удобно применять при программировании. Это удобство выяснится из следующего примера.

 

Задача: Известно, сколько дней в каждом месяце года. Сколько дней летом?

 

Сначала запишем программу традиционным способом.

Программа:

CONST dni: array [1..12] of Byte = (31,28,31,30,31,30,31,31,30,31,30,31);
VAR s,i:Integer;
begin
s:=0; {Сумматор летних дней}
for i:=6 to 8 do s:=s+dni[i]; {Летние месяцы - 6,7,8}
WriteLn(s)
end.

Недостаток приведенной программы - не самая лучшая наглядность, к тому же приходится самому на пальцах вычислять номера месяцев начала и конца лета (6 и 8). Паскаль имеет средства повысить наглядность и удобство таких программ. Запишем нашу программу по-новому, с использованием перечислимого типа данных:

TYPE mes = (january, february, march, april, may, june, july, august, september,
october, november, december);
CONST dni: array [january..december] of Byte =
(31,28,31,30,31,30,31,31,30,31,30,31);
VAR s:Integer;
i:mes;
begin
s:=0;
for i:=june to august do s:=s+dni[i];
WriteLn(s)
end.

Пояснения: Основное достижение нашей программы в том, что в операторе for можно написать june to august вместо 6 to 8, а в определении массива dni можно написать array[january..december] вместо array[1..12]. Для этого пришлось определить специальный перечислимый тип mes, перечислив в скобках произвольные имена месяцев, а переменную цикла i задать типом mes, а не Integer.

Синтаксис перечислимого типа:

(имя, имя, имя,...., имя)

Значения перечислимого типа можно использовать так же свободно, как и значения порядковых типов, например:

if i = february then dni[i]:= 29

Ограниченный тип (диапазон)

Задача: Поезд отправляется в путь в 22 часа и находится в пути 10 часов. Во сколько он прибывает на место назначения?

 

Ошибочная программа:

VAR Otpravlenie, Pribitie:Byte;

BEGIN

Otpravlenie:=22;

Pribitie:=Otpravlenie+10;

WriteLn(Pribitie)

END.

Эта программа вместо ответа “8” напечатает ответ “32” и ошибки не заметит. Паскаль не знает, что имеют смысл только те значения переменной Pribitie, которые находятся в диапазоне от 0 до 24. Это должен был знать программист, но он тоже не обратил на это внимания. Хотелось бы, чтобы Паскаль вместо выдачи неправильного ответа напоминал забывчивым программистам, что переменная вышла из имеющего смысл диапазона. Для этого программист должен иметь возможность этот диапазон Паскалю указать. Такую возможность дает применение диапазонов(ограниченных типов).

Вот программа, обнаруживающая собственную ошибку:

VAR Otpravlenie, Pribitie: 0..24;

BEGIN

Otpravlenie:=22;

Pribitie:=Otpravlenie+10;

WriteLn(Pribitie)

END.

Конструкция VAR Otpravlenie, Pribitie: 0..24 означает, что переменные Otpravlenie и Pribitie имеют право принимать значения целых чисел в диапазоне от 0 до 24.

Паскаль будет обнаруживать выход за диапазон только в том случае, когда вы установите флажок (крестик) в Options ®Compiler…®Compiler Options®Runtime Errors в положение Range Checking (см. часть IV – «Обзор популярных команд меню»).

Диапазон можно задавать для любого порядкового типа, например:

VAR Month:(january, february, march, april, may, june, july, august, september, october, november, december);

Spring:march..may;

Autumn:september..november;

tsifra:0..9;

Zaglavnie:’А’..’Я’

Диапазон является одним из видов порядковых типов.

Задание 108: Известны дата и время (месяц, день, час, минута) отплытия теплохода летом этого года из Москвы в Астрахань. Известно время в пути (в днях, часах и минутах). Оно не превышает 20 суток. Определить дату и время прибытия теплохода в Астрахань. Использовать диапазоны.

Вариант 1: Для простоты предположим, что путешествие начинается между 1 и 10 июня.

Вариант 2. Путешествие начинается в любой день лета. Определите еще и дни недели отправления и прибытия, если известно, какой день недели был 1 июня.