Защита силового ключа от перегрузки по току

 

Рис. 14. Защита по току

По заданию нам необходимо контролировать ток, потребляемый нагрузкой так, чтобы он не превышал значение 10А. Т.к., сигнал ОС должен сниматься так, чтобы при этом силовая часть преобразователя и СУ были гальванически развязаны, то это можно сделать с помощью трансформатора. Но ток нагрузки у нас постоянный и его невозможно снимать таким образом, поэтому будет сниматься ток транзистора – ток в первичной обмотке трансформатора TW 2, пропорциональный Iout. В общем, получаем, что ОC должна быть организована так, чтобы току Iout =10A соответствовало напряжение в 1В на 9 ножке микросхемы.

При Iout =10A ток первичной обмотки трансформатора TW 2 (коэффициент трансформации n = 0.68) равен . Зададимся коэффициентом трансформации TW 1 k = 50. Тогда .

. UR11 должно быть равно 1В. Тогда .

Конденсатор С5 также подключённый к выводу 9 микросхемы необходим для подавления помех и имеет малую ёмкость. Выберем её значение C5=100 пФ.

Конденсатор C2 ставится, чтобы убрать нежелательные всплески на входе RAMP, выбираем её равной C2=100пФ.

 

 

Моделирование схемы по усредненной модели

Анализ по постоянному току

 

 

Рис. 15. Усредненная модель преобразователя

 

Текст программы:

 

*

Vs 1 0 400

Vsac 2 1 ac 0

Rsac 2 0 1000

Eb 3 0 value={(V(2)*V(12)*n/4)}

Reb 3 4 0.02

L 4 5 700u

Vil 5 6 dc 0

Rc 6 13 4.2m

C 13 0 0.5u

Rn 6 0 {R}

.param R=1

.step param R 5.4 27 3.6

 

R13 6 7 50.5k

R14 7 0 3k

R3 7 8 1k

Rd1 8 9 1000k

Vr 9 0 3.06

R5 8 10 100k

Ea 10 0 table {(V(9)-V(8))}=(-10,1)(0,1)(0.005,6)(10,6)

Ed 11 0 value={limit(((V(10)-2.25)/1.8),.999,0.001)}

Vdac 12 11 ac 0

Rd 12 0 1000

 

.param n=0.68

.options ABSTOL=1e-10 VNTOL=1e-10 GMIN=1e-12 ITL4=350 RELTOL=1e-4 CHGTOL=1e-7

.tran 1m 300m 0 1m skipbp

.dc Vs 400 420 20

.probe

.end

 

 

Многовариантный расчет при различных значениях сопротивления нагрузки

 

 

Рис. 16. Напряжение на нагрузке

 

Анализ по переменному току

Расчет переходных характеристик

При расчете вводим цепь коррекции (С1 и R4), задаем импульс входного напряжения, импульс выходного тока и смотрим реакцию выходного напряжения. Подбирая параметры цепи коррекции добиваемся нужного результата.

Текст программы:

*

Vsp 1 0 pulse (400 420 0.1m 1u 1u 2m 4m)

Vsac 2 1 ac 0

Rsac 2 0 1000

Eb 3 0 value={(V(2)*V(12)*n/4)}

Reb 3 4 0.02

L 4 5 700u

Vil 5 6 dc 0

Rc 6 13 0.14m

C 13 0 1.5u

Rn 6 0 5.4

Isp 6 0 pulse (0 1 2m 1u 1u 2m 4m)

 

R13 6 7 50.5k

R14 7 0 3k

R3 7 8 1k

Rd1 8 9 1000k

Vr 9 0 3.06

R5 8 10 100k

R6 8 14 200

C2 14 10 100n

Ea 10 0 table {(V(9)-V(8))}=(-10,1)(0,1)(0.005,6)(10,6)

Ed 11 0 value={limit(((V(10)-2.25)/1.8),.999,0.001)}

Vdac 12 11 ac 1

Rd 12 0 1000

 

.param n=0.68

.options ABSTOL=1e-10 VNTOL=1e-10 GMIN=1e-12 ITL4=350 RELTOL=1e-4 CHGTOL=1e-7

.tran/op 10n 4m 0m 0.01m

.probe

.end

 

Рис. 16. Реакция на скачок

Расчет частотных характеристик.

При тех же параметрах цепи коррекции смотрим вид амплитудочастотной и фазочастотной характеристик.

Текст программы:

*

Vs 1 0 {P}

Vsac 2 1 ac 0

Rsac 2 0 1000

Eb 3 0 value={(V(2)*V(12)*n/4)}

Reb 3 4 0.02

L 4 5 700u

Vil 5 6 dc 0

Iac 6 0 ac 0

Rc 6 13 0.14m

C 13 0 1.5u

Rn 6 0 27

 

R13 6 7 50.5k

R14 7 0 3k

R3 7 8 1k

Rd1 8 9 1000k

Vr 9 0 3.06

R5 8 10 100k

R6 8 14 200

C2 14 10 100n

Ea 10 0 table {(V(9)-V(8))}=(-10,1)(0,1)(0.005,6)(10,6)

Ed 11 0 value={limit(((V(10)-2.25)/1.8),.999,0.001)}

Vdac 12 11 ac 1

Rd 12 0 1000

 

.param n=0.68

.options ABSTOL=1e-10 VNTOL=1e-10 GMIN=1e-12 ITL4=350 RELTOL=1e-4 CHGTOL=1e-7

.param P=1

.step param P 400 420 10

.ac dec 10 1 100k

 

.probe

.end

 

 

 

Рис. 17. Коэффициент усиления по напряжению

 

Рис. 18. Выходное сопротивление

 

Рис. 19. Петлевой коэффициент усиления